sys-devel/lld: Add 17.0.0_pre20230615 snapshot

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-06-17 21:10:13 +02:00
parent 5038070351
commit 6445845feb
2 changed files with 90 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST llvm-project-0e08374abb2c61a3ae5c24d5f60be3b548da9778.tar.gz 191661586 BLAKE2B 05e5328d8eb9972bd6399e8c0f5ab241a78e6591e63ee520180c4ff154df432ad96f49ddc615a2208f69ffbec539b201fffeaf4906011b7a961cbc3860126ffa SHA512 1d4429ecb2292e419ed6172cf251ba4a1448ed51424552ac48a159d0e3d3414777f7821382d1839b56f0c906fb0a147b1df4eecb071f8a5c11b0fc1d0d40d339
DIST llvm-project-14.0.6.src.tar.xz 105618228 BLAKE2B ee67c5407df8cef493b9c0004f15e428f22a536a17e5f4e3eb29a003b8a8ec0abe0fa3e072591161d5f30ef7d8867c1ce34d1b341ad858e93c00263499941a99 SHA512 6fc6eeb60fac698702d1aac495fc0161eb7216a1f8db2020af8fccec5837831f7cc20dc2a169bf4f0b5f520748280b4a86621f3697d622aa58faaa45dbfaad13
DIST llvm-project-14.0.6.src.tar.xz.sig 566 BLAKE2B cb658ad43d8ab6c43a5773aedadf0569c97b5ee4b1bd58eceb10e1879a30880c741c3d66bedd462c892309b688fb7b2673115a62d1f74d71ee375a578de9547f SHA512 b4a7b368532a7a4a24376cfa7db8f6d3478f6d4446474342fc00b474ecf466330cd0f16783209263c4c72d5fc7ddedfb11b95578842e700cfb7ee0bb34cc95d6
DIST llvm-project-15.0.7.src.tar.xz 110936452 BLAKE2B f3d277e2029157329e5be78b78af36b0826a1dfd9a337992499bf701e33149665bfc47d5e14978e38f342559629a559f8b2ce328705ba34fdf6830f5ae9721a5 SHA512 4836d3603f32e8e54434cbfa8ef33d9d473ac5dc20ebf9c67132653c73f4524931abd1084655eaee5f20bcfcb91bcc4bbc5c4a0b603ad0c9029c556e14dc4c52
@@ -0,0 +1,89 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit cmake flag-o-matic llvm llvm.org python-any-r1 toolchain-funcs
DESCRIPTION="The LLVM linker (link editor)"
HOMEPAGE="https://llvm.org/"
LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
SLOT="${LLVM_MAJOR}/${LLVM_SOABI}"
KEYWORDS=""
IUSE="+debug test zstd"
RESTRICT="!test? ( test )"
DEPEND="
~sys-devel/llvm-${PV}[debug=,zstd=]
sys-libs/zlib:=
zstd? ( app-arch/zstd:= )
"
RDEPEND="
${DEPEND}
!sys-devel/lld:0
"
BDEPEND="
sys-devel/llvm:${LLVM_MAJOR}
test? (
>=dev-util/cmake-3.16
$(python_gen_any_dep ">=dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
)
"
PDEPEND="
>=sys-devel/lld-toolchain-symlinks-16-r2:${LLVM_MAJOR}
"
LLVM_COMPONENTS=( lld cmake libunwind/include/mach-o )
llvm.org_set_globals
python_check_deps() {
python_has_version ">=dev-python/lit-${PV}[${PYTHON_USEDEP}]"
}
pkg_setup() {
LLVM_MAX_SLOT=${LLVM_MAJOR} llvm_pkg_setup
use test && python-any-r1_pkg_setup
}
src_unpack() {
llvm.org_src_unpack
# Directory ${WORKDIR}/llvm does not exist with USE="-test",
# but LLVM_MAIN_SRC_DIR="${WORKDIR}/llvm" is set below,
# and ${LLVM_MAIN_SRC_DIR}/../libunwind/include is used by build system
# (lld/MachO/CMakeLists.txt) and is expected to be resolvable
# to existent directory ${WORKDIR}/libunwind/include.
mkdir -p "${WORKDIR}/llvm" || die
}
src_configure() {
# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
use elibc_musl && append-ldflags -Wl,-z,stack-size=2097152
local mycmakeargs=(
-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/lib/llvm/${LLVM_MAJOR}"
-DBUILD_SHARED_LIBS=ON
-DLLVM_INCLUDE_TESTS=$(usex test)
)
use test && mycmakeargs+=(
-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-DLLVM_LIT_ARGS="$(get_lit_flags)"
-DPython3_EXECUTABLE="${PYTHON}"
)
tc-is-cross-compiler && mycmakeargs+=(
-DLLVM_TABLEGEN_EXE="${BROOT}/usr/lib/llvm/${LLVM_MAJOR}/bin/llvm-tblgen"
)
cmake_src_configure
}
src_test() {
local -x LIT_PRESERVES_TMP=1
cmake_build check-lld
}