xfce-base/xfce4-panel: Bump to 4.15.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

profiles/package.mask

@@ -567,6 +567,7 @@ dev-db/clickhouse
 # until upstream releases fixed versions.
 ~xfce-base/xfce4-panel-4.15.0
 ~xfce-base/xfce4-panel-4.15.1
+~xfce-base/xfce4-panel-4.15.2
 
 # Lars Wendler <polynomial-c@gentoo.org> (2019-10-16)
 # Depends on apache-2.2

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.14.3.tar.bz2 1304748 BLAKE2B 7e009e2afcc59b1d014fe776c439cd27c8ddb9b46215a9766f25f384802bc27a672201d0a73eff8aab3714822ee5f2c062806a60ccaf70cf6b5ec65f38f7e8a1 SHA512 c317741df1196a9f8d675c87732155f973022d1cb30a8815393980747d1569e8348c386253fc9056068c35fbdc13faefb4a0bef6678d072d51461c4aae909940
 DIST xfce4-panel-4.15.1.tar.bz2 1291026 BLAKE2B fe27e7238f3be3d53c42af185ceabfec133cac5f996af8d57eba456bb26c60e59d0e246d2d2f17b06eb35ad7fb08b009a453201b396021c34722d414c4c2034f SHA512 b635168043b1b0714796fae7d9b102ebfaa35b06ebca686cd3ba9124f21288f02009cf186aa09a93c1fd3343c769f38e8865c6aba98bd01d108f41e3ff041f80
+DIST xfce4-panel-4.15.2.tar.bz2 1302860 BLAKE2B 0c2ee5dac584cd1cae940872ca1130ae710e23f46089ee16241f03f87317d905937f1eb6c382140659e9b01669ccce26bf7e6e64e90207db3c7b7a7865c71674 SHA512 7f2e0d1de70db1778cd5a0c0ae4845ffef960b16f1e147ec6fd47543a6360e2281d8290bc055bc83993796bdbd97edeaca867a6790052bc07d8e2bffa412e5a2

xfce-base/xfce4-panel/xfce4-panel-4.15.2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.42
+	>=x11-libs/cairo-1
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libwnck:3
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-0.5:=
+	>=xfce-base/libxfce4ui-4.15.1:=
+	>=xfce-base/libxfce4util-4.13:=[introspection?]
+	>=xfce-base/xfconf-4.13:=
+	introspection? ( dev-libs/gobject-introspection:= )"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable vala)
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}