gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 5.43.4

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2020-12-25 09:34:07 +01:00
parent 4b8fe39708
commit 64271c9ec8
2 changed files with 65 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -2,3 +2,4 @@ DIST hypothesis-python-5.24.4.tar.gz 9054743 BLAKE2B 5c64c86ed58d8f0e4a07390b1b1
DIST hypothesis-python-5.41.3.tar.gz 9095982 BLAKE2B 3a1b7052b3f71d1f8139101d16f2f74c2d434514a201b7e04e5452ac2c5fbe7288d592c0020769f3a48f73347cdce53f507ab65db7bfb4f3823d0f7997e48058 SHA512 974dee6040222fa55729257cea4e3c4c049625a2a5dfddbc12667dbd58dfe31718474ce8e9de81519e998c7a0c8ff01920e0aa2bca9fb7100754e985177f4b69
DIST hypothesis-python-5.41.5.tar.gz 9098660 BLAKE2B 6caa742d34a3a2aeb6c6fdec3f8772e5221e1d0b2becc1362b657d383387f2a1152756222cfe86ffbb3e23a53e395050a16325d74ec9e03822a5c0020505b38e SHA512 b220a48e5746bacc6fa257f79feed0dc2c0a9f66862aba74806fb1ac3d06f380620410c9c46c377c50e4fa7c3171d5b31ce2759e7a3e0e2abd0920b237242dd6
DIST hypothesis-python-5.43.3.tar.gz 9103991 BLAKE2B e374edf17571c33e48dc8d259db2fb23b9cc358f56189ebd60f3e9141ade7759eede1bdbd91d924f144a20b1ea0b7ec19817559b7f82a90f026ac101a7feeabd SHA512 392fb794fc5ba06acd1e465cf1500f742d8b056148540778f1ec9c5065be66c0f514f0fa6872337869079636c71235d51d4c6722a63b03037b689edd6f09809f
DIST hypothesis-python-5.43.4.tar.gz 9104105 BLAKE2B 08b8c9ac7ac72afcc4556ae2167af7b4ab79d505da8c9f6a11c91d211f26ccf320c8f5ed41458f5e34f75614ad4aecdbf6df62275868dc079c037390dcbc9e08 SHA512 065e1bdd878eab35f38105e8da3f5cf108670a51fd48ea1996bebedf8c8a152386d0eb5284ed43d4e588695a408b3a455a2e4757430e31bb5dbf0ece1f64d294

64
dev-python/hypothesis/hypothesis-5.43.4.ebuild Normal file
View File

@@ -0,0 +1,64 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 eutils multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
IUSE="cli test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{6..9})
)
"
BDEPEND="
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
<dev-python/pytest-6.2[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
python_prepare() {
if ! use cli || [[ ${EPYTHON} != python* ]]; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
distutils_install_for_testing --via-root
pytest -vv tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
die "Tests fail with ${EPYTHON}"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}