gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/build: Bump to 1.4.4

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2026-04-23 05:19:59 +02:00
parent 7a6c22646e
commit 63a28ffb4f
2 changed files with 77 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/build/Manifest
View File

@@ -3,3 +3,4 @@ DIST build-1.4.0.gh.tar.gz 52372 BLAKE2B f7dac4752e908eee7e3f31af1da4c8854d5d1e3
DIST build-1.4.1.gh.tar.gz 89234 BLAKE2B 2447acae8dd03b37bd0be043f4428566a7cd7ec0b816ae2c2f5cf460741ff54310b0eb9a017f797662170a2c37cde6e41a4c6a031fee47da8ca2d2d2dcf439df SHA512 ed6e6329ee07c547a8cd7568d4f769b50e117a684c1d087380f896183db4bd6c4d921d75913525b301f994ff865d5acbe44290d8a1aa7c13c169979b942ceedc
DIST build-1.4.2.gh.tar.gz 89637 BLAKE2B 723fdbf83eb942eb744f9bd000bbea8fc231f648ff38024aa29c6b7768b80907dfb4fa7360bbb3b61efa2a1d5f6854922447a988e19e012729fc09f9c45a14f8 SHA512 f404a97391497a21c401976ec95cc9544602c6d8c81443b011ecffe8785a42a9f7b8e4f1d2fdd7eba0f74e4ca74aae1c19f66dfe7dd53eb08c0a0efa8934b67d
DIST build-1.4.3.gh.tar.gz 95503 BLAKE2B 71ba5fef2b9bd62eb1303d8d282ce5f6a18b7ba47632604a483f242d283295f8f52f2121a931607cbd9677e3e74cacb75f0a8992f147b07645fecd5121bb65ee SHA512 34158d518257aaeaffc0fba4275d4af9f62b2fa5fff80528aa968a33a3c2d91df96681167d964dd2922e2fcc694263a1a489ea1295f8dd4d75046ed7035ac266
DIST build-1.4.4.gh.tar.gz 95523 BLAKE2B f8f9247d4fbc27930a578fb4f0abba1e24af3e546f9b8af4fdef12e1d7c782b78805c917cbad77a9e8d2de9bd3e86613c8dc4a08fd5421e5d46dea948a3b8bdc SHA512 e296ad08b28b29e1233799ef25ad54265a19ced4c1c09db178776907d8ecc81f18d3f6bcc0f2197b250e5791e8c46362ba23a6a2ca455cab9d9dd308e4a8fc59

76
dev-python/build/build-1.4.4.ebuild Normal file
View File

@@ -0,0 +1,76 @@
# Copyright 2022-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=flit
PYTHON_TESTED=( python3_{11..14} pypy3_11 )
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_{13,14}t )
inherit distutils-r1
MY_P=${P/_p/.post}
DESCRIPTION="A simple, correct PEP517 package builder"
HOMEPAGE="
https://pypi.org/project/build/
https://github.com/pypa/build/
"
SRC_URI="
https://github.com/pypa/build/archive/${PV/_p/.post}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="test test-rust"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
dev-python/pyproject-hooks[${PYTHON_USEDEP}]
"
BDEPEND="
>=dev-python/setuptools-scm-6[${PYTHON_USEDEP}]
test? (
${RDEPEND}
$(python_gen_cond_dep '
>=dev-python/filelock-3[${PYTHON_USEDEP}]
>=dev-python/pip-22.3[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
>=dev-python/pytest-mock-2[${PYTHON_USEDEP}]
>=dev-python/pytest-rerunfailures-9.1[${PYTHON_USEDEP}]
>=dev-python/pytest-xdist-1.34[${PYTHON_USEDEP}]
>=dev-python/setuptools-56.0.0[${PYTHON_USEDEP}]
>=dev-python/virtualenv-20.0.35[${PYTHON_USEDEP}]
>=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
test-rust? (
!s390? ( !sparc? ( >=dev-python/uv-0.1.18 ) )
)
' "${PYTHON_TESTED[@]}")
)
"
python_test() {
if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
einfo "Skipping tests on ${EPYTHON}"
return
fi
local EPYTEST_DESELECT=(
# broken by uv being installed outside venv
tests/test_env.py::test_external_uv_detection_success
)
if ! has_version "dev-python/uv"; then
EPYTEST_DESELECT+=(
tests/test_env.py::test_uv_impl_install_cmd_well_formed
'tests/test_env.py::test_venv_creation[uv-venv+uv-None]'
)
fi
local EPYTEST_PLUGINS=( pytest-{mock,rerunfailures} )
local EPYTEST_XDIST=1
epytest -m "not network"
}