media-libs/libva-intel-driver: Version bump to 2.4.4

Signed-off-by: Matt Turner <mattst88@gentoo.org>

media-libs/libva-intel-driver/Manifest

@@ -1 +1,2 @@
 DIST intel-vaapi-driver-2.4.1.tar.bz2 2889762 BLAKE2B 25888ac7a1a42233c4b0269bd910c5161f99bf22c932b46e20c8c77ed0404bf99702dd9f11b73bc0fd76a3b012ffa1de6c6133cbd7be880428235de9cfcc6ad8 SHA512 1e9dc81ecd0b3640fccd1fb827a0ade0a1e5bbabe375130df159849e47ce98c8e879c65ddaaae11d16e916be76b507be69bc0c813494e37e7fca86b0b897a94f
+DIST libva-intel-driver-2.4.4.tar.gz 3936212 BLAKE2B b4b212285b35deb5cb3311a8d5cb39aa226442ed2f94bb043749eaef28b925eee3819d4ea4900a2ad5bfc98dcc9403af40cca7d77e7dfff531337d1d575587eb SHA512 a43c4117fc8a73e1b2f64aad7150dfa9d349b6f835a30db54bed842e249bd9525aaf27cd3a6e9c3570971a14917ab5d72ae960de5347e04034c426f52dd5599a

media-libs/libva-intel-driver/libva-intel-driver-2.4.4.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="intel-vaapi-driver"
+if [[ ${PV} = *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/irql-notlessorequal/intel-vaapi-driver"
+fi
+
+inherit meson-multilib
+
+DESCRIPTION="HW video decode support for Intel integrated graphics"
+HOMEPAGE="https://github.com/intel/intel-vaapi-driver"
+if [[ ${PV} != *9999* ]] ; then
+	SRC_URI="https://github.com/irql-notlessorequal/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="hybrid wayland X"
+RESTRICT="test" # No tests
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.52[video_cards_intel,${MULTILIB_USEDEP}]
+	>=media-libs/libva-2.4.0:=[X?,wayland?,${MULTILIB_USEDEP}]
+
+	hybrid? (
+		>=media-libs/intel-hybrid-codec-driver-2.0.0[X?,wayland?]
+	)
+
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+		virtual/opengl[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Denable_hybrid_codec=$(usex hybrid true false)
+		-Dwith_wayland=$(usex wayland)
+		-Dwith_x11=$(usex X)
+	)
+	meson_src_configure
+}