dev-python/pypy3_10-exe: Backport upstream fixes to 7.3.13_p2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pypy3_10-exe/Manifest

@@ -1,2 +1,3 @@
 DIST pypy3.10-gentoo-patches-7.3.13.tar.xz 4776 BLAKE2B 9f0ef159c8aa2d3edb5ee0e14be694c4a7c1165d70b16e9b13b6e59da7334354cc8593186a2ff47d4a0ce8c76abdf4a3c12ec3ffdd7a90cc4f30b39c259c3ee7 SHA512 86bfbf7f26f259c0850074c9062544ee091f7a65359cb17dae3ec287841e7a812d7185cb552f3546acdde3965efe0e6c0fb728c30b64779fca10be2f7c4d634f
+DIST pypy3.10-gentoo-patches-7.3.13_p2.tar.xz 7948 BLAKE2B 3978db108a1ab3e471f878e3480d4419262c34137f43c2e11168c85704f8c72769bea5bca9613ba5fb762b7f88c77f55070dc6a28e8a92ffa6f95d74fb5891ad SHA512 dd8c0f74f22f45608addaf362ef0dc8acee3c5a02bed7c557883ca97d4e2bdfe47dbf6621a4da01cc97956550aa252622237b85c642fb33100065237689c2abb
 DIST pypy3.10-v7.3.13-src.tar.bz2 23067819 BLAKE2B 6e2bfd83bcf16feef006dad39ab6d8f452418ee6bc4043edaa590db702f39275e775004bdba762736a901da94cb5274cd34f2811461048d46ac0f4af04158702 SHA512 16fbc76558152b3eadca999d56197a6bf906cbb7bb75035ccd3501372af0f0c22533d22ba231a40b7c02afa11f0d692a6ae85ba6d5e1607b737b8c68209b7c43

dev-python/pypy3_10-exe/pypy3_10-exe-7.3.13_p2.ebuild

@@ -0,0 +1,127 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit check-reqs pax-utils toolchain-funcs
+
+PYPY_PV=${PV%_p*}
+PYVER=3.10
+MY_P="pypy${PYVER}-v${PYPY_PV/_}"
+PATCHSET="pypy${PYVER}-gentoo-patches-${PV}"
+
+DESCRIPTION="PyPy3 executable (build from source)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+SLOT="${PYPY_PV}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+jit low-memory ncurses cpu_flags_x86_sse2"
+
+RDEPEND="
+	app-arch/bzip2:0=
+	dev-libs/expat:0=
+	dev-libs/libffi:0=
+	>=sys-libs/zlib-1.1.3:0=
+	virtual/libintl:0=
+	ncurses? ( sys-libs/ncurses:0= )
+	!dev-python/pypy3-exe-bin:${SLOT}
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/pypy
+"
+
+check_env() {
+	if use low-memory; then
+		CHECKREQS_MEMORY="1750M"
+		use amd64 && CHECKREQS_MEMORY="3500M"
+	else
+		CHECKREQS_MEMORY="3G"
+		use amd64 && CHECKREQS_MEMORY="6G"
+	fi
+
+	check-reqs_pkg_pretend
+}
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+}
+
+src_configure() {
+	tc-export CC
+
+	local jit_backend
+	if use jit; then
+		jit_backend='--jit-backend='
+
+		# We only need the explicit sse2 switch for x86.
+		# On other arches we can rely on autodetection which uses
+		# compiler macros. Plus, --jit-backend= doesn't accept all
+		# the modern values...
+
+		if use x86; then
+			if use cpu_flags_x86_sse2; then
+				jit_backend+=x86
+			else
+				jit_backend+=x86-without-sse2
+			fi
+		else
+			jit_backend+=auto
+		fi
+	fi
+
+	local args=(
+		--no-shared
+		$(usex jit -Ojit -O2)
+
+		${jit_backend}
+
+		pypy/goal/targetpypystandalone
+		--withmod-bz2
+		$(usex ncurses --with{,out}mod-_minimal_curses)
+	)
+
+	local interp=( pypy )
+	if use low-memory; then
+		local -x PYPY_GC_MAX_DELTA=200MB
+		interp+=( --jit loop_longevity=300 )
+	fi
+
+	# translate into the C sources
+	# we're going to build them ourselves since otherwise pypy does not
+	# free up the unneeded memory before spawning the compiler
+	set -- "${interp[@]}" rpython/bin/rpython --batch --source "${args[@]}"
+	echo -e "\033[1m${@}\033[0m"
+	"${@}" || die "translation failed"
+}
+
+src_compile() {
+	emake -C "${T}"/usession*-0/testing_1
+}
+
+src_install() {
+	cd "${T}"/usession*-0 || die
+	newbin "testing_1/pypy${PYVER}-c" "pypy${PYVER}-c-${PYPY_PV}"
+	insinto "/usr/include/pypy${PYVER}/${PYPY_PV}"
+	doins *.h
+	pax-mark m "${ED}/usr/bin/pypy${PYVER}-c-${PYPY_PV}"
+}