dev-python/nox: Bump to 2025.02.09

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/nox/Manifest

@@ -1 +1,2 @@
 DIST nox-2024.10.09.gh.tar.gz 4003528 BLAKE2B 51bf42870eac462fdb87e897c225c8262703ccc222d5c463e45d91acf08e4211153f60f72450e3fb964d4ca386501bfa88559e8cff38d55aa2f22310a17d7911 SHA512 51d1f70ba94d01abd10ba3a12896facd13a7a2881496221b6fa9d0a43ff947303b0cc975a29169a3d9e0174277e23e0bc4b1137b2774c1abffa23a48c9d69a11
+DIST nox-2025.02.09.gh.tar.gz 4021040 BLAKE2B d0185d6ad2dc7ef881f6f6dd7a38d0e8cb7398d7cb6b59bd6b27593e8e13011ef96673c14f75402804af104066b160e765726ed0bd7a647584e785a861f5a685 SHA512 431e9aed5e596d74298f4d7c1d41bded2edf271824cd69be09dbb434d38de07809c15a59707a9925f048d33f51fa6369340bb2d5c726cfb2c4afdf3f9303aed2

dev-python/nox/nox-2025.02.09.ebuild

@@ -0,0 +1,73 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Flexible test automation for Python"
+HOMEPAGE="
+	https://github.com/wntrblm/nox/
+	https://pypi.org/project/nox/
+"
+SRC_URI="
+	https://github.com/wntrblm/nox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/attrs-23.1[${PYTHON_USEDEP}]
+	>=dev-python/colorlog-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/dependency-groups-1.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.9[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.14.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/py[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove upper bounds from dependencies
+	sed -i -e 's:<[0-9.]*,::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: conda?
+		'tests/test_sessions.py::TestSessionRunner::test__create_venv_options[nox.virtualenv.CondaEnv.create-conda-CondaEnv]'
+		# Internet
+		tests/test_virtualenv.py::test_uv_install
+		tests/test_main.py::test_noxfile_script_mode
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# hardcoded CPython assumption
+				tests/test_tox_to_nox.py::test_commands_with_requirements
+				tests/test_tox_to_nox.py::test_skipinstall
+				tests/test_tox_to_nox.py::test_trivial
+				tests/test_tox_to_nox.py::test_usedevelop
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o tmp_path_retention_policy=all
+}