media-video/openshot: bump version to 2.4.4

- Add dev-python/PyQt5[gui,widgets] to RDEPEND.
- Add USE=doc.
- Add python3_7 to PYTHON_COMPAT.
- Use xdg instead of xdg-utils for default pkg_*().
- EAPI=7.
- Update SRC_URI.

Closes: https://bugs.gentoo.org/635970
Closes: https://bugs.gentoo.org/637694
Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Stefan Strogin <steils@gentoo.org>

media-video/openshot/Manifest

@@ -1 +1,2 @@
+DIST openshot-2.4.4.tar.gz 63065376 BLAKE2B 2ee00f24d699d5935a182c394821f215a27ba2701d493f51299c19cf99452ca4df2e5b86f7a6e5734e6194e39e5b7995eb94be168c0e9f7bc7a3b78206277304 SHA512 efa71f97a83b89e691b7dab09288ba7d3e91eb25119669fa8f6e28becb8d4cb3e60a923f936ee4ff9a593d016fe3a6b0348153cff937ab7d21a5517de5dfa10c
 DIST openshot-qt-2.4.0.tar.gz 60710408 BLAKE2B 33c8abe7ba3122ae720163d6ab91d367ee282b94d3d8986fdccf4f9efae832f54af7f946472c781a17f7e54083028762952d02d7139e6815cd0d44e80515c728 SHA512 95778effa5b02a467c44741384b0f43bf90343d4f450d5fcc2319ff1c3bee212338435dd8c781e0ff111a704aacdce3dbfb6bdcf62afa1f59bbb0668b58074ca

media-video/openshot/openshot-2.4.4.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE=xml
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg
+
+MY_PN="${PN}-qt"
+
+DESCRIPTION="Free, open-source, non-linear video editor to create and edit videos and movies"
+HOMEPAGE="https://www.openshot.org/"
+SRC_URI="https://github.com/OpenShot/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-python/httplib2[${PYTHON_USEDEP}]
+	dev-python/PyQt5[${PYTHON_USEDEP},gui,svg,webkit,widgets]
+	dev-python/pyzmq[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=media-libs/libopenshot-0.2.3[python,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	distutils-r1_python_prepare_all
+	# prevent setup.py from trying to update MIME databases
+	sed -i 's/^ROOT =.*/ROOT = False/' setup.py || die
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+}