dev-python/truststore: New package, v0.7.0

A replacement for dev-python/certifi, required by dev-python/pdm now.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/truststore/Manifest

@@ -0,0 +1 @@
+DIST truststore-0.7.0.gh.tar.gz 24953 BLAKE2B c94c832410ecdf101d5b5f27fa1e48205e5fbafe4b51a2583d7a44b2501cff43f693017c572f08f9a0bb7ed6fd3bf1a73401e1b628e8a690f34d1c9b7577c755 SHA512 e3a4e751984668c571004d111df9f5e449db3269b7d6b4224dd6aad03d2a066260c9dc8e1f1573b9fd062bf4b1fe486510915ebc1cd9ff20e5626c033f56b519

dev-python/truststore/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">sethmlarson/truststore</remote-id>
+		<remote-id type="pypi">truststore</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/truststore/truststore-0.7.0.ebuild

@@ -0,0 +1,46 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Verify certificates using native system trust stores"
+HOMEPAGE="
+	https://github.com/sethmlarson/truststore/
+	https://pypi.org/project/truststore/
+"
+SRC_URI="
+	https://github.com/sethmlarson/truststore/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+PROPERTIES="test_network"
+RESTRICT="test"
+
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio -p pytest_httpserver
+}