gui-libs/libadwaita: Version bump to 1.3.3

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31369
Signed-off-by: Matt Turner <mattst88@gentoo.org>

gui-libs/libadwaita/Manifest

@@ -1 +1,2 @@
 DIST libadwaita-1.3.2.tar.xz 3132728 BLAKE2B ca9839af1016fae291d8d40dfc29c82ec92c2a22dc5b164290f755b40d01dfe0112afcf0c95101e37874ccf97b5ee2b5d5543315ef1144dc0ebaa73fa820afdb SHA512 86591af2a699931518e211a41844a23d5aaaccb6196d39b28f4768129852c33267e9a66a91dc274711a31df38b84f39feb7c7d22ae54b946a16cea4865ac83e8
+DIST libadwaita-1.3.3.tar.xz 3145696 BLAKE2B 1aa9de9cb5852cb2c57f6442c0f71d1bc3a5b62fa930a0a3aebdbc56b2050525be314362e1b886ae7fb9009491913eb8cd0f0921a42ccac0f49ef19478a836b7 SHA512 1ff0ad1cb04c920404eb177743f5caeedb20173e99e8654f1a157928ee00b0d8cb03dc411ad9617d44591709ecc805043a60c63adde1a2d17252a94c6a28a2be

gui-libs/libadwaita/libadwaita-1.3.3.ebuild

@@ -0,0 +1,65 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit gnome.org meson python-any-r1 vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME applications"
+HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+IUSE="+introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.9.5:4[introspection?]
+	dev-libs/fribidi
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-libs/appstream-glib )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		# Never use gi-docgen subproject
+		--wrap-mode nofallback
+
+		-Dprofiling=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		-Dgtk_doc=false # we ship pregenerated docs
+		$(meson_use test tests)
+		-Dexamples=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test --timeout-multiplier 2
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/gtk-doc/html
+	# This will install libadwaita API docs unconditionally, but this is intentional
+	doins -r "${S}"/doc/libadwaita-1
+}