app-text/cherrytree: version bump to 1.3.0

Signed-off-by: Joel Anderson <joel@goatshriek.com>
Closes: https://github.com/gentoo/gentoo/pull/41181
Signed-off-by: Sam James <sam@gentoo.org>

app-text/cherrytree/Manifest

@@ -1 +1,2 @@
 DIST cherrytree_1.2.0.tar.xz 4735884 BLAKE2B 47f2aef52bb1fea23be8f5db3d2ec9f4c6a596bb6136350098f870688e34e5662241f188f1c94331af2119b59546c95fbe8254bdbb187990b514f9d21fd76214 SHA512 729e8227eb1f0616e110153ac2139cc7019ed5e1a949c8be40fd2235ee5d2e0f0b1925c57d72c9b443852e5b80a50793e4e903b7df41da8e95a172210f7ec035
+DIST cherrytree_1.3.0.tar.xz 4749468 BLAKE2B 31c953e114f704316bca09f32e13cfeb7e1f0147ba3e5f9a72e07fa1c808577be926f18dc3aa868c912a369b0cbc28630bc54136fd98f9d4d3d63248b33ef3ee SHA512 e7b061aed33ad55c1fc7f7dd43b01db6c36ba414c32f996c86c9a64899e6d0cf7825637350c8dcf252d5495b8d956a675b34607854177d6f01615ad9d4953c78

app-text/cherrytree/cherrytree-1.3.0.ebuild

@@ -0,0 +1,88 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake python-any-r1 virtualx xdg
+
+DESCRIPTION="A hierarchical note taking application (C++ version)"
+HOMEPAGE="https://www.giuspen.com/cherrytree/"
+
+SRC_URI="https://github.com/giuspen/${PN}/releases/download/v${PV}/${P/-/_}.tar.xz"
+S="${WORKDIR}"/${P/-/_}
+
+# GPL-3 — future/src/ct (CherryTree)
+# LGPL-2.1 — future/src/7za (7zip)
+# MIT — future/src/fmt (libfmt)
+LICENSE="GPL-3 LGPL-2.1 MIT"
+
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+
+IUSE="nls test"
+
+RDEPEND="app-i18n/uchardet
+	app-text/gspell:=
+	>=dev-cpp/glibmm-2.64.2:2
+	dev-cpp/gtkmm:3.0
+	x11-libs/gtksourceview:4
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/pangomm:1.4
+	dev-db/sqlite:3
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/libfmt:=
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	>=dev-libs/spdlog-1.5:=
+	>=x11-libs/vte-0.70.2:2.91
+	net-misc/curl
+	x11-libs/cairo[X]
+	x11-libs/gtk+:3[X]
+	x11-libs/pango[X]"
+
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-cpp/gtest )"
+
+src_prepare() {
+	# disable compress man pages
+	sed -i -e \
+		'/install(FILES/s|${MANFILE_FULL_GZ}|${CMAKE_SOURCE_DIR}/data/cherrytree.1|' \
+		CMakeLists.txt || die
+
+	# python_fix_shebang .
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXEC="${PYTHON}"
+		-DUSE_NLS=$(usex nls)
+		-DBUILD_TESTING=$(usex test)
+		-DUSE_SHARED_FMT_SPDLOG=ON
+		-DUSE_SHARED_GTEST_GMOCK=$(usex test)
+	)
+
+	if use test; then
+		mycmakeargs+=(
+			-DAUTO_RUN_TESTING=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	# the export test suite fails if more than one job is used for testing, so
+	# we force it to a single job here, for more detail see
+	# https://github.com/giuspen/cherrytree/pull/2663
+	MAKEOPTS="${MAKEOPTS} -j1" virtx cmake_src_test
+}