dev-qt/qtchooser: new snapshot

Package-Manager: Portage-2.3.8, Repoman-2.3.3

dev-qt/qtchooser/Manifest

@@ -1 +1,2 @@
 DIST qtchooser-0_p20151008.tar.xz 31308 SHA256 121e90dd70054701c52b0d555ffa2a55192439afded88197f17d7b2ca28fa2e8 SHA512 d6fd56e839b7ce7abbd42300d76d06d67fabb5ca36a6f6a39493b7770599372c4795a90cafeea8cceff8da7ea7f6639d74f76a8241a808364a41905fa3d084c6 WHIRLPOOL 8e5fc7d1b30d06990af87737e7d5a4b210f0f30ef2d8d7a17b7ef91e02afdb9bce7240c7f291d557855a277c4d5c4c3f452c416ea29a9f1f9a23c9aeface4ae3
+DIST qtchooser-0_p20170803.tar.xz 32012 SHA256 b8cb86c69351fa1acbb96dac6b5e76c6cde73c1a259d56a64c7891726aefde88 SHA512 320d898617ad52392fe24834e99ace685dac84e3a7edb1f6e6358baadb6658a51b02ae1af465ef5e081485a002c787c6884b6e1637ffd0406767fe7555fc32a7 WHIRLPOOL 5d8efa42b4f864bf3b3660f8adaa0ca65c20b9d94d682cb45a623c4b53fd81c366d268c417a586a22348448fb76cb67bcf8acd472dc4f101d07efc975ad23131

dev-qt/qtchooser/qtchooser-0_p20170803.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils toolchain-funcs
+
+DESCRIPTION="Qt4/Qt5 version chooser"
+HOMEPAGE="https://code.qt.io/cgit/qtsdk/qtchooser.git/"
+SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${P}.tar.xz"
+
+LICENSE="|| ( LGPL-2.1 GPL-3 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="test"
+
+DEPEND="test? (
+		dev-qt/qtcore:5
+		dev-qt/qttest:5
+	)"
+RDEPEND="
+	!<dev-qt/assistant-4.8.6:4
+	!<dev-qt/designer-4.8.6:4
+	!<dev-qt/linguist-4.8.6:4
+	!<dev-qt/pixeltool-4.8.6:4
+	!<dev-qt/qdbusviewer-4.8.6:4
+	!<dev-qt/qt3support-4.8.6:4
+	!<dev-qt/qtbearer-4.8.6:4
+	!<dev-qt/qtcore-4.8.6:4
+	!<dev-qt/qtdbus-4.8.6:4
+	!<dev-qt/qtdeclarative-4.8.6:4
+	!<dev-qt/qtdemo-4.8.6:4
+	!<dev-qt/qtgui-4.8.6:4
+	!<dev-qt/qthelp-4.8.6:4
+	!<dev-qt/qtmultimedia-4.8.6:4
+	!<dev-qt/qtopengl-4.8.6:4
+	!<dev-qt/qtopenvg-4.8.6:4
+	!<dev-qt/qtphonon-4.8.6:4
+	!<dev-qt/qtscript-4.8.6:4
+	!<dev-qt/qtsql-4.8.6:4
+	!<dev-qt/qtsvg-4.8.6:4
+	!<dev-qt/qttest-4.8.6:4
+	!<dev-qt/qtwebkit-4.8.6:4
+	!<dev-qt/qtxmlpatterns-4.8.6:4
+"
+
+qtchooser_make() {
+	emake \
+		CXX="$(tc-getCXX)" \
+		LFLAGS="${LDFLAGS}" \
+		prefix="${EPREFIX}/usr" \
+		"$@"
+}
+
+src_compile() {
+	qtchooser_make
+}
+
+src_test() {
+	pushd tests/auto >/dev/null || die
+	eqmake5
+	popd >/dev/null || die
+
+	qtchooser_make check
+}
+
+src_install() {
+	qtchooser_make INSTALL_ROOT="${D}" install
+
+	keepdir /etc/xdg/qtchooser
+
+	# TODO: bash and zsh completion
+	# newbashcomp scripts/${PN}.bash ${PN}
+}