gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 17:09:10 -07:00
Code Issues Projects Releases Wiki Activity

dev-db/mydumper: add 0.19.3.3

Browse Source 
Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/43093
Signed-off-by: Petr Vaněk <arkamar@gentoo.org>
This commit is contained in:
Tomáš Mózes
2025-07-21 12:42:29 +00:00
committed by Petr Vaněk
parent f989e72e86
commit 604f3ab466
2 changed files with 63 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
dev-db/mydumper/Manifest
View File

@@ -5,3 +5,5 @@ DIST mydumper-0.18.1-1.tar.gz 199785 BLAKE2B a21404e73ae7b992c53371512015d50056b
DIST mydumper-0.18.1-1_docs.tar.gz 943632 BLAKE2B 9e0879b092a1ce1073751c3d3174bce812cfb35ff4e3a58846ca61cc7655c84d426e68b32f2091a4788a796d7e5fb80abcaa07c5c5fed9317faf5dabaa1c59b5 SHA512 0df911f03a97ca6b5bc65ccea3bedae36a94690e7b53f9014972e860af37c8b7814832a9759cf91f642770452e2016e3ae3fd8dd0852108727f491e5f9d22cd1
DIST mydumper-0.18.2-7.tar.gz 242488 BLAKE2B 9f7663941ac83fd30c7ccec3b7bd0f2fa84cb360170802755d6b85586f7da151e7fc59842088a6f72a342830c885cee6f25702dd8d7bd9f94fcf5bc6bf6053cc SHA512 c4ef10fb69117dc8ec5b01b948dce929045f4dde0232390b9887a34f13ed42284e38255ccbc63bf8f73bb4e31b0b9a3be1523561f7adf33f74204f51da413316
DIST mydumper-0.18.2-7_docs.tar.gz 943632 BLAKE2B 9e0879b092a1ce1073751c3d3174bce812cfb35ff4e3a58846ca61cc7655c84d426e68b32f2091a4788a796d7e5fb80abcaa07c5c5fed9317faf5dabaa1c59b5 SHA512 0df911f03a97ca6b5bc65ccea3bedae36a94690e7b53f9014972e860af37c8b7814832a9759cf91f642770452e2016e3ae3fd8dd0852108727f491e5f9d22cd1
DIST mydumper-0.19.3-3.tar.gz 843289 BLAKE2B b812829c66a2f8a392119bc11f11a5ab4a767d9e4033e5d7a1fa94fa29c4eba6104bbfb193844d4aeff1f394d4a1e0342286f37e3304c5b94fe2a8d4b36f1b23 SHA512 6a6e3c18684a9d67cc622d3563819b82e886a6e54d1036e7659216eda863feb9e1bc3b08378ce75019248ef68ef6ed356c8edf643e90172352e65e44e39a796c
DIST mydumper-0.19.3-3_docs.tar.gz 947356 BLAKE2B bd2402f32dd3b26e08c2ae0a33a1bfd8afc37a9bddb520c4bc1ab1a7c8eb3b31333a5bcdb96bfcc1eaa47b40361b1c7efc1de623cd104e6518e78074acd70aef SHA512 9cadf5799b78265c95f6fe9cded4c34cc62a78143afbde062b38329a8727f60cc2405d01e189a2d1929364e0e32bf658827e700c5a3cbe0f65856d2fbb3b35f6

61
dev-db/mydumper/mydumper-0.19.3.3.ebuild Normal file
View File

@@ -0,0 +1,61 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
MY_PV="$(ver_rs 3 -)"
MY_P="${PN}-${MY_PV}"
DOCS_COMMIT="af9dcd8d9c66cf445237f9a060d07c2a4dd3d382"
DESCRIPTION="A high-performance multi-threaded backup (and restore) toolset for MySQL"
HOMEPAGE="https://github.com/mydumper/mydumper"
SRC_URI="https://github.com/mydumper/mydumper/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz
https://github.com/mydumper/mydumper_docs/archive/${DOCS_COMMIT}.tar.gz -> ${MY_P}_docs.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
RDEPEND="
app-arch/zstd
dev-db/mysql-connector-c:=
dev-libs/glib:2
dev-libs/libpcre2:=
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? (
dev-python/furo
dev-python/sphinx-inline-tabs
)
"
PATCHES=(
"${FILESDIR}/${PN}-0.13.1-atomic.patch" #654314
"${FILESDIR}/${PN}-0.18-Do-not-overwrite-the-user-CFLAGS.patch"
"${FILESDIR}/${PN}-0.16-cmake-docs.patch"
)
src_prepare() {
# copy in docs
rm -rv "${WORKDIR}"/"${MY_P}"/docs || die
mv -v "${WORKDIR}/${PN}_docs-${DOCS_COMMIT}" "${WORKDIR}/${MY_P}/docs" || die
# https://pypi.org/project/sphinx-copybutton/ not yet in Gentoo
sed -i "s/'sphinx_copybutton',//g" "${WORKDIR}/${MY_P}/docs/_build/conf.py.in" || die
# fix doc install path
sed -i -e "s|share/doc/mydumper|share/doc/${PF}|" docs/CMakeLists.txt || die
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(-DBUILD_DOCS=$(usex doc))
cmake_src_configure
}