media-sound/snd: bump to 22.9

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
This commit is contained in:
Miroslav Šulc
2022-11-23 10:08:51 +01:00
parent 4470b680fe
commit 60113e8f19
2 changed files with 107 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST snd-17.4.tar.gz 15096338 BLAKE2B ca054977caacd2ea4c1b14f50c31d3b4cc6b206a58529ee5537ec80e51acb72c1b8baad6db9729270fe07067c097f16e630e1f7a81521ac0532f5b5689fb963c SHA512 cbbc546fe4a3ef758c5372edbdae4db29457c559eafa08854819917e153ce850f5ab302da68dee826f99c26f10769aae8c6df6ea8434614f084f21d0dbbc5c88
DIST snd-22.8.tar.gz 14696217 BLAKE2B 6d90e1a51f862d17985831f676a01e61c9cce44f623c8db5d8a0a30cb3909823b5361a20ce5a19bfdb846c0d5237fcd9183be0a9970cfa6e9e02c69911090e6f SHA512 a6c007a1c17973f6bc4badcca72b310b4e53d3a8b1831f026fca230ae9925ab3c53eb6a97015220fd929b7ecb14c7922ba2113d6c7a6626406ec4d361b7b228d
DIST snd-22.9.tar.gz 14704873 BLAKE2B 788a0d77571b13cac0bb191bd88e0d18d5a6808fbee170c8cb3237a2bdc8b20a72cd3a4360cf0632c1746bec317b367ebf6344ac05d9a5485d54a77268ab96cf SHA512 641f49438dd71285249d2da6f36f30ca52ec8f8fc8189af7815abff054db7651d8da54798509c77d93d542d09bb11e3ad6662aec51e9ba1c7a6a1672bb0eba48
+106
View File
@@ -0,0 +1,106 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic
DESCRIPTION="Snd is a sound editor"
HOMEPAGE="https://ccrma.stanford.edu/software/snd/"
SRC_URI="https://ccrma.stanford.edu/software/${PN}/${P}.tar.gz"
LICENSE="Snd 0BSD BSD-2 HPND GPL-2+ LGPL-2.1+ LGPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="alsa doc fftw gmp gsl gui jack ladspa notcurses opengl oss portaudio pulseaudio readline ruby +s7"
RDEPEND="
alsa? ( media-libs/alsa-lib )
fftw? ( sci-libs/fftw:3.0= )
gmp? (
dev-libs/gmp:=
dev-libs/mpc
dev-libs/mpfr:=
)
gsl? ( sci-libs/gsl:= )
gui? ( x11-libs/motif:0 )
jack? ( virtual/jack )
ladspa? ( media-libs/ladspa-sdk )
notcurses? ( dev-cpp/notcurses )
opengl? ( virtual/opengl )
portaudio? ( media-libs/portaudio )
pulseaudio? ( media-sound/pulseaudio )
readline? ( sys-libs/readline:= )
ruby? ( dev-lang/ruby:* )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
REQUIRED_USE="
?? ( portaudio pulseaudio )
?? ( ruby s7 )"
PATCHES=(
"${FILESDIR}"/${PN}-22.8-undefined-oss_sample_types.patch
)
src_prepare() {
default
sed -i -e "s:-O2 ::" configure.ac || die
eautoreconf
}
src_configure() {
# Workaround executable sections QA warning (bug #348754)
append-ldflags -Wl,-z,noexecstack
local myeconfargs=(
$(use_with alsa)
$(use_with fftw)
$(use_with gmp)
$(use_with gsl)
$(use_with gui)
$(use_with jack)
$(use_with ladspa)
$(use_with notcurses)
$(use_with oss)
$(use_with portaudio)
$(use_with pulseaudio)
$(use_with ruby)
$(use_with s7)
)
if ! use ruby && ! use s7 ; then
myeconfargs+=( --without-extension-language )
fi
econf "${myeconfargs[@]}"
}
src_compile() {
emake snd
# Do not compile ruby extensions for command line programs since they fail
sed -i -e "s:HAVE_RUBY 1:HAVE_RUBY 0:" mus-config.h || die
emake sndplay sndinfo
}
src_install() {
dobin snd sndplay sndinfo
if use ruby ; then
insinto /usr/share/snd
doins *.rb
fi
if use s7 ; then
insinto /usr/share/snd
doins *.scm
fi
use doc && HTML_DOCS=( *.html pix/*.png )
einstalldocs
dodoc HISTORY.Snd
}