dev-libs/libunibreak: bump to 7.0

Signed-off-by: Andrey Grozin <grozin@gentoo.org>

dev-libs/libunibreak/Manifest

@@ -1 +1,2 @@
 DIST libunibreak-6.1.tar.gz 855733 BLAKE2B 05963c0131c73e7064dc34a2db88ea121f3ec8a7dbd83adaccbcea61a02af8de6b5a26b39df46f6295a5f6572db20a7c3bf83e882fa99a7a2bbe42b378b26488 SHA512 8ffde29a9b90ddcbfabb61d7302ffe3b17473cd6d30fe1a4403d857e6191291d7e7a6f23bde58654155ed95f4a0f31e082cdf424a82da46722a811291ef38c2f
+DIST libunibreak-7.0.tar.gz 175378 BLAKE2B 9ba72b60aadf10d0e7da8905a45727a6ee747f4bb13085f8b49dae2d78db36ca3a67641a7d132fa77e6365ce9f41d0226d747cb1ae42e056bfa8fa68e45430ad SHA512 50271605be1645698df7ef5b97ae6bbc75b7228ea1aa26a261f33afd8e264e63c37c190d8d7f3a93f87d60b627a68ec90f2f7f55ef08486e5a8bd667c4a372f6

dev-libs/libunibreak/libunibreak-7.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Line and word breaking library"
+HOMEPAGE="http://vimgadgets.sourceforge.net/libunibreak/
+	https://github.com/adah1972/libunibreak"
+SRC_URI="https://github.com/adah1972/${PN}/archive/refs/tags/${PN}_${PV/./_}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${PN}_${PV/./_}
+
+LICENSE="ZLIB"
+SLOT="0/7"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc +man static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="man? ( app-text/doxygen )"
+
+src_prepare() {
+	default
+	./bootstrap || die
+
+	if use man; then
+		echo 'GENERATE_MAN=YES' >> Doxyfile || die
+		echo 'GENERATE_HTML=NO' >> Doxyfile || die
+	fi
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+	if use man; then
+		doxygen || die 'doxygen failed'
+		pushd "${S}"/doc/man > /dev/null
+		mv man3 x || die
+		mkdir man3 || die
+		for h in graphemebreak linebreak linebreakdef unibreakbase unibreakdef wordbreak; do
+			mv x/${h}.h.3 man3/ || die "man ${h} not found"
+		done
+		rm -rf x || die
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/html/. )
+	default
+	find "${D}" -name '*.la' -delete || die
+	if use man; then
+		doman doc/man/man3/*.3
+	fi
+}