gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

kde-apps/kget: 24.05.1 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2024-06-13 17:45:07 +02:00
parent 1ce99e3754
commit 5f6fbf57ee
2 changed files with 71 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/kget/Manifest
View File

@@ -1,2 +1,3 @@
DIST kget-23.08.5.tar.xz 5572688 BLAKE2B 60cc3da0f3dd4dd2cda4fd1851d74aaedc6dd5d4a7dfcc689f3f32f1c5632b067ce01e4b972d424243dc96a446ae33d59faa3abec55ed44a31691163f53d16a7 SHA512 c8ded9a4786db55b22734f0432d87bd260bca74f300e9dcf1ec38973269068f0b7b77d9943082cf2db0a8c37fbb644828b7e186ae83fb527be1706728de53e57
DIST kget-24.05.0.tar.xz 4909016 BLAKE2B 3d7e7a63b8cd7000b3f8c37cce1721c1eba301b22f03fde02cb5683f61bc3690a755825e52417ebd07f409b9672e0e34e7674f45f095a4ddfdc7805bb06f8df5 SHA512 6900d9320a2778cf9ceb137dbd7b03cc398d0f246e9343b14530e5030d0f4bd2b4b47a907a16aae400e0ec1230a7438cd56663c169dc9e9bd08467f82b54d3ca
DIST kget-24.05.1.tar.xz 4908844 BLAKE2B 01533485cd5692ed211b7bf6c8711492300bfd0123283c7e890e24ea13f71d17da4a14d3e673a9ef446d759f45129e4bca822e5ef916dd62ecdaa0fbe9f3f24b SHA512 3a6424912b3f92938a3f2b650b7f780561c9f3a5fadd94c226cfe1f50186d7644b4261b28285f6ee1faaf8f16570dbf4d38ecc5c5e71c90f904081d5dcf92812

70
kde-apps/kget/kget-24.05.1.ebuild Normal file
View File

@@ -0,0 +1,70 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="forceoptional"
ECM_TEST="forceoptional"
KFMIN=6.3.0
QTMIN=6.6.2
inherit ecm gear.kde.org
DESCRIPTION="Advanced download manager by KDE"
HOMEPAGE="https://apps.kde.org/kget/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64"
IUSE="bittorrent gpg mms sqlite"
RDEPEND="
>=app-crypt/qca-2.3.7:2[qt6]
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,sql,widgets,xml]
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/knotifyconfig-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/kwallet-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
bittorrent? ( net-libs/libktorrent:6 )
gpg? ( >=app-crypt/gpgme-1.23.1-r1:=[qt6] )
mms? ( media-libs/libmms )
sqlite? ( dev-db/sqlite:3 )
"
DEPEND="${RDEPEND}
dev-libs/boost
"
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package bittorrent KTorrent6)
$(cmake_use_find_package gpg Gpgmepp)
$(cmake_use_find_package gpg QGpgmeQt6)
$(cmake_use_find_package mms LibMms)
$(cmake_use_find_package sqlite SQLite3)
)
ecm_src_configure
}
src_test() {
# bug 756817: schedulertest fails, see also upstream commit 45735cfa
# filedeletertest hangs.
local myctestargs=(
-E "(schedulertest|filedeletertest)"
)
ecm_src_test
}