x11-wm/herbstluftwm: Version 0.8.0

Package-Manager: Portage-2.3.98, Repoman-2.3.22
Closes: https://bugs.gentoo.org/716842
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

x11-wm/herbstluftwm/Manifest

@@ -1 +1,2 @@
 DIST herbstluftwm-0.7.2.tar.gz 245506 BLAKE2B 72d0bb2a77e519161d193ac7b2b9f1f878ccb6cfe4914b6c75d060e2daa0bec4203ee4ebf203b9fa1dfb844d71d50aa7c03257c78aa22e906bf42519d1e592af SHA512 abb49bbc3de9a0ef619ce7063c1cea0d0d25ab2195c53dc0d33e061ad24060da4bbe9b99b9b9126028cdf68b462d4fcc8d1534431e4892d571ff897a68d2113c
+DIST herbstluftwm-0.8.0.tar.gz 358434 BLAKE2B 770aa66c2e8926d5f73b36ae2376e33ac92f9f72e2d45f55caa3247710f88b0eef72bed8a7242ba4ef298d9e8a7af3768114bd5149aa5596aa4682caef7e9e91 SHA512 108ef76e6f81d98742c37a1a5ecf1ce998d6fc8ee43642acb08716a5bee2e7a691f1f8defe9c81ecc8930f8b29ba7a49efe2eb00a3699c22de1a5f841266873c

x11-wm/herbstluftwm/herbstluftwm-0.8.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs cmake-utils
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/herbstluftwm/herbstluftwm"
+	BDEPEND="app-text/asciidoc"
+else
+	SRC_URI="https://herbstluftwm.org/tarballs/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	BDEPEND=""
+fi
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="https://herbstluftwm.org/"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="examples xinerama zsh-completion"
+
+DEPEND="
+	>=dev-libs/glib-2.24:2
+	x11-libs/libX11
+	x11-libs/libXext
+	xinerama? ( x11-libs/libXinerama )
+"
+RDEPEND="
+	${DEPEND}
+	app-shells/bash
+	zsh-completion? ( app-shells/zsh )
+"
+BDEPEND+="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	sed -i \
+		-e '/^install.*LICENSEDIR/d' \
+		-e '/set(DOCDIR / s#.*#set(DOCDIR ${CMAKE_INSTALL_DOCDIR})#' \
+		CMakeLists.txt || die
+
+	mycmakeargs=(
+		-DWITH_XINERAMA=$(usex xinerama)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if ! use examples; then
+		rm -r "${ED}"/usr/share/doc/${PF}/examples || die
+	fi
+
+	if ! use zsh-completion; then
+		rm -r "${ED}"/usr/share/zsh || die
+	fi
+}