dev-python/hatchling: add 1.7.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/hatchling/Manifest

@@ -1,3 +1,4 @@
 DIST hatch-hatchling-v1.5.0.gh.tar.gz 232265 BLAKE2B 4fd57f7610831a025b9b0dddb89c4fe484d32d0b76a2d0cdafb76730b37c54af42ef27dc1c4d73061d888ce75806bd8f0fc70f5d39a077bd534716cf4e4a4db8 SHA512 9e5498b9da3a1f756e0f3e40daa63e45017588332da4197ac83b8402219bb9501b9c498dd881c5812b2b8903af591e4c6146aaf6dea8cc7b6bc664a85dee74e6
 DIST hatch-hatchling-v1.6.0.gh.tar.gz 233428 BLAKE2B 5ce5a2a94c9021919f50f90a96f37713a739fe08e1d6a5955a3af369d6c37beece1a4c22b1883e689e500f219101fb67a700231b8d0d22432150b34a6cee22bd SHA512 be23b81cca96cb93321938e0ac7455efc2e388e910c1b64a7d611a37681b5bd6aa89c4fe165a7a2f7ce2dd11ea3598aaeaaab80869e689aac0afdce915b8f567
 DIST hatch-hatchling-v1.7.0.gh.tar.gz 249253 BLAKE2B a294b87172b16bda86a90f2d9577bfa7ea9bc21e6644006cb141b762df96bb62e7e828e1c147c6409e6b7278a0bd00cb6ee67d01b203dec110fc272cfae6fd92 SHA512 6a3c807674891ff23ca0b2f00e62900e9e4752888cf6c8647ac20ec6b76a13c23e17a52989d4661d03bed3e33e682a09b877ae6c99bfc707a28ddde754ea9386
+DIST hatch-hatchling-v1.7.1.gh.tar.gz 1471608 BLAKE2B 52d7d1f8a45f5dd6573676b8f6946b843c5368ba0b0a53d1a30d48c1087350eea54335fbc76816f334526238451ab8075586212386bb18edc0c3b3cfc5224b3c SHA512 dfffc8586ee3ff5c7f1f277be1e653efef70fca5377c12c16bb05c1deeb5cf5eccc5cd58d0923a32c7a8b3701621f6be881709bb836734170a08b103b841107f

dev-python/hatchling/hatchling-1.7.1.ebuild

@@ -0,0 +1,74 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{8..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/editables-0.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	epytest tests/backend
+}