net-misc/gsutil: Version bump to 4.45

Also add me and zmedico as maintainers.

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
This commit is contained in:
Patrick McLean
2019-10-24 15:37:33 -07:00
committed by Patrick McLean
parent 4ed2004c85
commit 5e9b591fb3
3 changed files with 93 additions and 1 deletions
+1
View File
@@ -1 +1,2 @@
DIST gsutil_4.41.tar.gz 3685987 BLAKE2B 7586d6c64c87c27e4c5f3e86372bfe6d7fdfbdcbe4146308ed497d86b6e3fb984a79d3f07ba3ed055ac09bfe70eef893b8b764a46921703c48c8e54e49cac7eb SHA512 f96500a4761cb244039ba20ccb328b143134a74822990538585116fe6afa6f9e23cfecc9958e34d5deb4291edc9cbe97c6176b3a0f0136ed6e8e81303b5b8c4a
DIST gsutil_4.45.tar.gz 3695514 BLAKE2B 9b129ae1e87620b2430368818929fbd884319cd2cf7788275ba556f873b13700b9333c59b753202d8c88a81eaa47e223f39f6ded26adf8d16144324763528886 SHA512 9b21162afcfcd063976be51151d1d51aaeac1a32c2b7d0ee79aaccb28f5202f93623b39ed994bd796ab508a56363fea69429fe42cd770cff3c7c8352a4956212
+84
View File
@@ -0,0 +1,84 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_6 )
inherit distutils-r1
DESCRIPTION="command line tool for interacting with cloud storage services"
HOMEPAGE="https://github.com/GoogleCloudPlatform/gsutil"
SRC_URI="http://commondatastorage.googleapis.com/pub/${PN}_${PV}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="test"
RDEPEND="${PYTHON_DEPS}
>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
>=dev-python/boto-2.49.0[${PYTHON_USEDEP}]
>=dev-python/crcmod-1.7[${PYTHON_USEDEP}]
>=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
>=dev-python/gcs-oauth2-boto-plugin-2.5[${PYTHON_USEDEP}]
>=dev-python/google-apitools-0.5.30[${PYTHON_USEDEP}]
dev-python/google-reauth-python[${PYTHON_USEDEP}]
>=dev-python/httplib2-0.11.3[${PYTHON_USEDEP}]
>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
>=dev-python/monotonic-1.4[${PYTHON_USEDEP}]
>=dev-python/oauth2client-4.1.2[${PYTHON_USEDEP}]
>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
>=dev-python/retry-decorator-1.0.0[${PYTHON_USEDEP}]
>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
>=dev-python/PySocks-1.01[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]"
PATCHES=(
"${FILESDIR}/gsutil-4.41-tests.patch"
)
S="${WORKDIR}/${PN}"
DOCS=( README.md CHANGES.md )
# needs to talk to Google to run tests
RESTRICT="test"
python_prepare_all() {
distutils-r1_python_prepare_all
sed -e 's/boto==/boto>=/' \
-e 's/mock==/mock>=/' \
-e 's/oauth2client==/oauth2client>=/' \
-e 's/SocksiPy-branch==/PySocks>=/' \
-i setup.py || die
# For debugging purposes, temporarily uncomment this in order to
# show hidden tracebacks.
#sed -e 's/^ except OSError as e:$/&\n raise/' \
# -e 's/def _HandleUnknownFailure(e):/&\n raise/' \
# -i gslib/__main__.py || die
# create_bucket raised ResponseNotReady
sed -e 's/test_cp_unwritable_tracker_file/_&/' \
-e 's/test_cp_unwritable_tracker_file_download/_&/' \
-i gslib/tests/test_cp.py || die
sed -e 's/\(executable_prefix =\).*/\1 [sys.executable]/' \
-i gslib/commands/test.py || die
# IOError: close() called during concurrent operation on the same file object.
sed -e 's/sys.stderr.close()/#&/' \
-i gslib/tests/testcase/unit_testcase.py
# Package installs 'test' package which is forbidden and likely a bug in the build system
rm -rf "${S}/test" || die
sed -i -e '/recursive-include test/d' MANIFEST.in || die
}
python_test() {
BOTO_CONFIG=${FILESDIR}/dummy.boto \
${PYTHON} gslib/__main__.py test -u || die "tests failed"
}
+8 -1
View File
@@ -1,7 +1,14 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<!-- maintainer-needed -->
<maintainer type="person">
<email>chutzpah@gentoo.org</email>
<name>Patrick McLean</name>
</maintainer>
<maintainer type="person">
<email>zmedico@gentoo.org</email>
<name>Zac Medico</name>
</maintainer>
<upstream>
<remote-id type="google-code">gsutil</remote-id>
<remote-id type="github">GoogleCloudPlatform/gsutil</remote-id>