dev-vcs/gitg: Bump to 50

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-vcs/gitg/Manifest

@@ -1 +1,2 @@
 DIST gitg-44.tar.xz 10629352 BLAKE2B 2c96b9e59ae04b8f9d760526007a564d7eda6bc2130b9e4970c55049da08e7a9f16c98bb8aa1a6d12e6baebc4b795a7947419cf9180b1f073cc79d9c54f83781 SHA512 3a5eadcd80aad42344adbe8783ba7e6d91dd5abe8343987e51db32db73205eb660d1c98bbfacbc6399a8c285fbd8ceb56ee87bc76569d45ca5c69bf1926e6bee
+DIST gitg-50.tar.xz 11248492 BLAKE2B 6585da805e1a3735945a19a8ab894a95e8cb7f41d60b0be258fffc62ed182a4d4b17a62a081b321afeabf1cd3b2103c8b76f175e3bc8bb6d4f586c11d5c13881 SHA512 24ba94640a666fb413cb035d41c173c61596205b294ffb353ab53b158649581f046df041cd5d5d3634afe5efa7146ef50068ab796de8fb5c3178af70703078c9

dev-vcs/gitg/gitg-50.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+inherit gnome.org gnome2-utils meson python-r1 vala xdg
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gitg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/gpgme:=
+	app-crypt/libsecret[vala]
+	>=app-text/gspell-1:=[vala]
+	>=dev-libs/glib-2.38:2[dbus,introspection]
+	>=dev-libs/gobject-introspection-1.82.0-r2:=
+	dev-libs/json-glib
+	dev-libs/libgee:0.8[introspection]
+	>=dev-libs/libgit2-glib-1.2.0[ssh]
+	dev-libs/libgit2:=[threads(+)]
+	>=dev-libs/libpeas-1.38.0:0=[gtk]
+	>=dev-libs/libxml2-2.9.0:2=
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=gui-libs/libhandy-1.5.0
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-4.0.3:4
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/libgit2-glib-1.0.0[vala]
+"
+BDEPEND="
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	$(vala_depend)
+"
+
+PATCHES=(
+	# Upstream patches from Debian
+	"${FILESDIR}/${PN}-44-gir-2.0.patch"
+)
+
+src_prepare() {
+	default
+
+	# it doesn't do anything in DESTDIR mode, except for failing
+	# when python3 symlink is not present
+	echo "#!/bin/sh" > meson_post_install.py || die
+}
+
+src_configure() {
+	vala_setup
+
+	local emesonargs=(
+		$(meson_use glade glade_catalog)
+		# we install the module manually anyway
+		-Dpython=false
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi.overrides
+		python_foreach_impl python_domodule libgitg-ext/GitgExt.py
+	fi
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}