dev-python/pdm: Bump to 2.25.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pdm/Manifest

@@ -1 +1,2 @@
 DIST pdm-2.25.4.tar.gz 2663701 BLAKE2B 41bf5446b125788c9f136aea47f5911a173197868afc9bbb587820fae5c65c4621ad75369a4b6959c125e1a08428473f242e199c24ec50f8f8246b9312ee3d7a SHA512 afe6c0305ee41871e99ac03099376795072732b99697cb30edd06b1f36ec0bed6ce27396f445865f4395ed11c0e3f6bd4c7afc0bf0631c396636865257a5424a
+DIST pdm-2.25.6.tar.gz 2664707 BLAKE2B b8dd9ed141cc70494882626e27b6434cc9d8583dbec20ebf2eb417845e4501125780e70c3d81e9308b774dd6cce008e0fa676573590239d453175581e647b384 SHA512 6c768ab05973daf703d3ee417ba0d5919a050f3451bf8b53ef8246101e3258c85b993caa7898e64fa13abddbaec08c90ac147d966fc9d9d2eb6e68ade9d33d79

dev-python/pdm/pdm-2.25.6.ebuild

@@ -0,0 +1,83 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.7.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-0.0.32[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.1[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.06.06[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.2.0[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{httpserver,httpx,mock,rerunfailures} )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+	# remove pkgutil namespace magic, as it doesn't work and makes
+	# dev-python/pdm-backend tests test the wrong package
+	rm src/pdm/__init__.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+		# TODO: random regression?
+		tests/cli/test_python.py::test_find_python
+		# TODO
+		tests/test_formats.py::test_export_from_pylock_not_empty
+	)
+
+	epytest -m "not network and not integration and not path"
+}