net-misc/dropbox: bump to 99.4.501

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

net-misc/dropbox/Manifest

@@ -1,2 +1,4 @@
 DIST dropbox-lnx.x86-98.4.158.tar.gz 96568004 BLAKE2B fc9ae4cf5d9ad1798dd5d55bf90cd5e77e7cd7405626fb55d4693e26d028d97a81d2843eb03d60de94f552cc446fffa4caa679ba3a750098a58549fc78ff4c67 SHA512 ce6432bbec1ec024e6753a93f2d0eed3af60de521f411f52efb63767eb500a85da80102a011e077fd9953d4827403d02143b186f30137ef7a338cb01664911a2
+DIST dropbox-lnx.x86-99.4.501.tar.gz 97126978 BLAKE2B 38476b8c0b36c385c69c44588c5b3ea227a8f7db2b1bc08c75558dfae6e962c5f9df4ce82ddb8afaa53b4b6522ec37f2cc5cfffce6d5b293a64b98333c33641b SHA512 01d91cb5be1439fd1d2e47b93da570650cbc21aa4ba0bff05f066ed5c5a60d162a7a5e3eb343e6a2ca48709964b29570b94cc8702a1064a8fce0779acb6ea14e
 DIST dropbox-lnx.x86_64-98.4.158.tar.gz 100751556 BLAKE2B 8ebbfa7101852e531edf9c6b3318c14418c95a0e618ce3725411e6fb1dbae70860de9b0daeba4c824fff0b3bd5f9a9347a4fe09c1433f76be3b3cc86184d769e SHA512 00db27742f8dff9d3fb96f06fcefdb30450b675b3c3cd35df717908455a8b1ca0419efff8932022d82c89dd3fccca183bc1bb16a1fb25c0505c49dfd03b06a19
+DIST dropbox-lnx.x86_64-99.4.501.tar.gz 101375862 BLAKE2B 46c03250bd2c2d480b67a645c03fc8fc0343aeb5906afd1807b49bfb44d07606b59a61fa79fcad48cb4029969f457ef347d5f1394dbf53b10586bc05b068295e SHA512 4d8b350aa8cbc9cc5491c8978cbe56eb8e08110f48dd4187d7287a46847d8a4316158ea39e09e707a135a10424e8c6bc2a66b3cf4f9b8529fc0cbf755744a118

net-misc/dropbox/dropbox-99.4.501.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop pax-utils systemd xdg
+
+DESCRIPTION="Dropbox daemon (pretends to be GUI-less)"
+HOMEPAGE="https://www.dropbox.com/"
+SRC_URI="
+	amd64? ( https://clientupdates.dropboxstatic.com/dbx-releng/client/dropbox-lnx.x86_64-${PV}.tar.gz )
+	x86? ( https://clientupdates.dropboxstatic.com/dbx-releng/client/dropbox-lnx.x86-${PV}.tar.gz )"
+
+LICENSE="BSD-2 CC-BY-ND-3.0 FTL MIT LGPL-2 openssl dropbox"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+IUSE="+librsync-bundled selinux X"
+
+RESTRICT="mirror strip"
+
+QA_PREBUILT="opt/.*"
+QA_EXECSTACK="opt/dropbox/dropbox"
+
+BDEPEND="dev-util/patchelf"
+
+# Be sure to have GLIBCXX_3.4.9, #393125
+RDEPEND="
+	X? (
+		dev-libs/glib:2
+		media-libs/fontconfig
+		media-libs/freetype
+		virtual/jpeg
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXinerama
+		x11-libs/libXxf86vm
+		x11-libs/pango[X]
+		x11-misc/wmctrl
+		x11-themes/hicolor-icon-theme
+	)
+	!librsync-bundled? ( <net-libs/librsync-2 )
+	selinux? ( sec-policy/selinux-dropbox )
+	app-arch/bzip2
+	dev-libs/libffi-compat:6
+	dev-libs/popt
+	net-misc/wget
+	>=sys-devel/gcc-4.2.0
+	sys-libs/zlib
+	sys-libs/ncurses-compat:5"
+
+src_unpack() {
+	unpack ${A}
+	mkdir -p "${S}" || die
+	mv "${WORKDIR}"/.dropbox-dist/* "${S}" || die
+	mv "${S}"/dropbox-lnx.*-${PV}/* "${S}" || die
+	rmdir "${S}"/dropbox-lnx.*-${PV}/ || die
+	rmdir .dropbox-dist || die
+}
+
+src_prepare() {
+	default
+
+	rm -vf libGL.so.1 libX11* libdrm.so.2 libffi.so.6 libpopt.so.0 wmctrl || die
+	# tray icon doesnt load when removing libQt5* (bug 641416)
+	#rm -vrf libQt5* libicu* qt.conf plugins/ || die
+	if use X ; then
+		mv images/hicolor/16x16/status "${T}" || die
+	else
+		rm -vrf images || die
+	fi
+	if use librsync-bundled ; then
+		patchelf --set-rpath '$ORIGIN' librsyncffi_native.*.so || die
+	else
+		rm -vf librsync.so.1 || die
+	fi
+	patchelf --set-rpath '$ORIGIN' \
+		apex._apex.*.so \
+		nucleus_python.*.so \
+		tprt.*.so \
+		|| die
+	pax-mark cm dropbox
+	mv README ACKNOWLEDGEMENTS "${T}" || die
+}
+
+src_install() {
+	local targetdir="/opt/dropbox"
+
+	insinto "${targetdir}"
+	doins -r *
+	fperms a+x "${targetdir}"/{dropbox,dropboxd}
+	dosym "${targetdir}/dropboxd" "/opt/bin/dropbox"
+
+	use X && doicon -s 16 -c status "${T}"/status
+
+	make_desktop_entry "${PN}" "Dropbox" "dropboxstatus-logo"
+
+	newinitd "${FILESDIR}"/dropbox.initd dropbox
+	newconfd "${FILESDIR}"/dropbox.conf dropbox
+	systemd_newunit "${FILESDIR}"/dropbox_at.service-r2 "dropbox@.service"
+
+	dodoc "${T}"/{README,ACKNOWLEDGEMENTS}
+}