mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
media-libs/libplacebo: add 6.287.0_rc1 (unkeyworded)
mpv-9999 now depends on >=5.266 (with USE=libplacebo) which is unreleased bare this release candidate. Add to offer the option to skip tracking libplacebo-9999 as well and prepare version bounds given this seems incompatible with old mpv. Note may not punctually bump further _rc if they are released, please file a bug if you want one. Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST libplacebo-glad-2.0.4.tar.gz 599932 BLAKE2B 788d2b70222fd09eea02515bdf3cbc147540631bf35fe39f12aa21fdbabf3d229f4234a430217dfaf3363934b8be12dd6a19871049a7b117deb8260ec69f8c67 SHA512 328d0dbe33e69f846d1c54226c6675694404f41e53c4762e6013c7bfe76b0700f0b28f4117a2018a09c9c23ccb6ad94d7b20882fefc2513941a4515686c9b9e7
|
||||
DIST libplacebo-v5.264.1.tar.gz 725394 BLAKE2B 421de50ef5e2270e3ba32dd85d92d816a374257442b535face6cb8501d565652aae530b86a7d717c9352c6a82ca665ff7d91c2d9768365780cbbe4f48d1d3276 SHA512 305f43b71f078f4113def43c444df667dfbdd2a6a34d3b457b15da0b3499ca97ec9a8acbd151d58c8e1a593ace3d8aa61067b32556c6bae451efbb217d60a731
|
||||
DIST libplacebo-v6.287.0-rc1.tar.bz2 615586 BLAKE2B 0c3cea0345cd535dcf3220789748840769c42842cb3d86ac0989e6f4ba03002be7bdc0b50ceb24e3b94065582a48cda128d198e6a569cd6d3c7be36e4f81f1f3 SHA512 9c0bc369f2885415f78c0d1b36a758e56acdf3f7ef34c41bd8153f8f643d4e29ff41ba1ca6fd10b39d1daa96dff9d22dd9affc37d599825f9f9b01480530294d
|
||||
|
||||
@@ -0,0 +1,98 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
inherit meson-multilib python-any-r1
|
||||
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
EGIT_REPO_URI="https://code.videolan.org/videolan/libplacebo.git"
|
||||
inherit git-r3
|
||||
else
|
||||
MY_PV=${PV/_/-}
|
||||
GLAD_PV=2.0.4
|
||||
SRC_URI="
|
||||
https://code.videolan.org/videolan/libplacebo/-/archive/v${MY_PV}/libplacebo-v${MY_PV}.tar.bz2
|
||||
opengl? ( https://github.com/Dav1dde/glad/archive/refs/tags/v${GLAD_PV}.tar.gz -> ${PN}-glad-${GLAD_PV}.tar.gz )"
|
||||
S="${WORKDIR}/${PN}-v${MY_PV}"
|
||||
# unkeyworded _rc for use with mpv-9999 if not using libplacebo-9999
|
||||
#KEYWORDS="~amd64 ~ppc64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Reusable library for GPU-accelerated image processing primitives"
|
||||
HOMEPAGE="https://code.videolan.org/videolan/libplacebo/"
|
||||
|
||||
LICENSE="LGPL-2.1+ opengl? ( MIT )"
|
||||
SLOT="0/$(ver_cut 2 ${PV}.9999)" # soname
|
||||
IUSE="glslang lcms llvm-libunwind +opengl +shaderc test unwind +vulkan"
|
||||
RESTRICT="!test? ( test )"
|
||||
REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
|
||||
|
||||
# libglvnd is used with dlopen() through glad (inc. egl/gles)
|
||||
RDEPEND="
|
||||
lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
|
||||
opengl? ( media-libs/libglvnd[${MULTILIB_USEDEP}] )
|
||||
shaderc? ( media-libs/shaderc[${MULTILIB_USEDEP}] )
|
||||
!shaderc? ( glslang? ( dev-util/glslang:=[${MULTILIB_USEDEP}] ) )
|
||||
unwind? (
|
||||
llvm-libunwind? ( sys-libs/llvm-libunwind[${MULTILIB_USEDEP}] )
|
||||
!llvm-libunwind? ( sys-libs/libunwind:=[${MULTILIB_USEDEP}] )
|
||||
)
|
||||
vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )"
|
||||
# vulkan-headers is required even with USE=-vulkan (bug #882065)
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
dev-util/vulkan-headers"
|
||||
BDEPEND="
|
||||
$(python_gen_any_dep 'dev-python/jinja[${PYTHON_USEDEP}]')
|
||||
virtual/pkgconfig"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-5.229.1-llvm-libunwind.patch
|
||||
"${FILESDIR}"/${PN}-5.229.1-python-executable.patch
|
||||
)
|
||||
|
||||
python_check_deps() {
|
||||
python_has_version "dev-python/jinja[${PYTHON_USEDEP}]"
|
||||
}
|
||||
|
||||
src_unpack() {
|
||||
if [[ ${PV} == 9999 ]]; then
|
||||
local EGIT_SUBMODULES=( $(usev opengl 3rdparty/glad) )
|
||||
git-r3_src_unpack
|
||||
else
|
||||
default
|
||||
if use opengl; then
|
||||
rmdir "${S}"/3rdparty/glad || die
|
||||
mv glad-${GLAD_PV} "${S}"/3rdparty/glad || die
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# typically auto-skipped, but may assume usable opengl/vulkan then hang
|
||||
sed -i "/tests += 'opengl_surfaceless.c'/d" src/opengl/meson.build || die
|
||||
sed -i "/tests += 'vulkan.c'/d" src/vulkan/meson.build || die
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
local emesonargs=(
|
||||
-Ddemos=false #851927
|
||||
$(meson_use test tests)
|
||||
$(meson_feature lcms)
|
||||
-Dlibdovi=disabled # TODO: package libdovi, ask if you need this
|
||||
$(meson_feature opengl)
|
||||
$(meson_feature opengl gl-proc-addr)
|
||||
$(meson_feature shaderc)
|
||||
$(usex shaderc -Dglslang=disabled $(meson_feature glslang))
|
||||
$(meson_feature unwind)
|
||||
$(meson_feature vulkan)
|
||||
$(meson_feature vulkan vk-proc-addr)
|
||||
-Dvulkan-registry="${ESYSROOT}"/usr/share/vulkan/registry/vk.xml
|
||||
)
|
||||
|
||||
meson_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user