www-client/microsoft-edge-beta: automated bump (99.0.1150.38)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>
This commit is contained in:
Stephan Hartmann
2022-03-11 17:19:53 +01:00
parent 6dc21da19f
commit 5d9875b066
2 changed files with 117 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST microsoft-edge-beta_99.0.1150.21-1_amd64.deb 117614562 BLAKE2B 5f2f6499a52c1a51f74d5ccc725093ec1bd9bdc826d992d4f40f2bd2fd4b213632acda7fba996c2319add053a5e7c553573fe0b1c836b9872f3b910412ab11a0 SHA512 185e75390196b5960247350fd6df47004146e001cc60e622f6f2ec9f6e7f83d1a98870f30590d775aaa39154f6abc98c11ff0305e43c45638e60279d0ec43596
DIST microsoft-edge-beta_99.0.1150.25-1_amd64.deb 117593274 BLAKE2B 86dcb9a5d253aa665bf0c471fda02f6dd934b1a288a7c4c3d99bb4189a30323454570e7e3f86cce5b9376fef5cbe4dc1325562a6a3c9a302157a592c0310667b SHA512 4c4981f3af40563bcbf905061817211b5ddd218d47e4408ae62cb13e71dc9c7a346372994c19b60fc79b6ed679fccd19eb2152df6c996dcddaaf62dab6277742
DIST microsoft-edge-beta_99.0.1150.30-1_amd64.deb 117576018 BLAKE2B 82271f024f73d1e880db48667e7055723ba42c2aa0391754bf09138b965a918757f82f956590e06b0a0a517fc1c89eda715061670877abfd4d69b596ece2e31c SHA512 bf00bc41d7c056c62c7668597345f1202c6d0181623c995c1869dfd12f7a662a09a8a880fe0ab485fa36659b85b8fb7c485d2971f2f4d30bb17e784bb2c7e521
DIST microsoft-edge-beta_99.0.1150.38-1_amd64.deb 117592384 BLAKE2B 09ab1757c9da9f5115fe5cd9d1f31a56549b32766777c13dcf635df8a6fae0bff93af777986cf2441b15bafc4af21acb179cd94683003d34f8dcacb3cc0e7564 SHA512 a24d8ade143c49c898411a7e788cff02495085e423fd397a2872514ebb0ab1331ed68e3c4ce18f99c56f95cbbe962d1d0a47306ed7b8cfc5bb2ff314afd137cf
@@ -0,0 +1,116 @@
# Copyright 2011-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
inherit chromium-2 desktop pax-utils unpacker xdg
DESCRIPTION="The web browser from Microsoft"
HOMEPAGE="https://www.microsoft.com/en-us/edge"
if [[ ${PN} == microsoft-edge ]]; then
MY_PN=${PN}-stable
else
MY_PN=${PN}
fi
KEYWORDS="-* ~amd64"
MY_P="${MY_PN}_${PV}-1"
SRC_URI="https://packages.microsoft.com/repos/edge/pool/main/m/${MY_PN}/${MY_P}_amd64.deb"
LICENSE="microsoft-edge"
SLOT="0"
RESTRICT="bindist mirror strip"
IUSE="+mip"
RDEPEND="
app-accessibility/at-spi2-atk:2
app-accessibility/at-spi2-core:2
app-misc/ca-certificates
dev-libs/atk
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
media-fonts/liberation-fonts
media-libs/alsa-lib
media-libs/mesa[gbm(+)]
net-misc/curl[ssl]
net-print/cups
sys-apps/dbus
sys-apps/util-linux
sys-libs/glibc
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:3[X]
x11-libs/libdrm
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/libxcb
x11-libs/libxkbcommon
x11-libs/libxshmfence
x11-libs/pango
x11-misc/xdg-utils
mip? ( app-crypt/libsecret )
"
QA_PREBUILT="*"
QA_DESKTOP_FILE="usr/share/applications/microsoft-edge.*\\.desktop"
S=${WORKDIR}
EDGE_HOME="opt/microsoft/msedge${PN#microsoft-edge}"
pkg_nofetch() {
eerror "Please wait 24 hours and sync your tree before reporting a bug for microsoft-edge fetch failures."
}
pkg_pretend() {
# Protect against people using autounmask overzealously
use amd64 || die "microsoft-edge only works on amd64"
}
pkg_setup() {
chromium_suid_sandbox_check_kernel_config
}
src_unpack() {
:
}
src_install() {
dodir /
cd "${ED}" || die
unpacker
rm _gpgorigin || die
rm -r etc usr/share/menu || die
mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
gzip -d usr/share/doc/${PF}/changelog.gz || die
gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
if [[ -L usr/share/man/man1/${PN}.1.gz ]]; then
rm usr/share/man/man1/${PN}.1.gz || die
dosym ${MY_PN}.1 usr/share/man/man1/${PN}.1
fi
local suffix=
[[ ${PN} == microsoft-edge-beta ]] && suffix=_beta
[[ ${PN} == microsoft-edge-dev ]] && suffix=_dev
local size
for size in 16 24 32 48 64 128 256 ; do
newicon -s ${size} "${EDGE_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
done
if ! use mip; then
rm "${EDGE_HOME}"/libmip_{core,protection_sdk}.so || die
fi
pax-mark m "${EDGE_HOME}/msedge"
}