net-voip/yate: add 6.1.0

econf options were not passed due to a missing \

Fixes: https://bugs.gentoo.org/674342
Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11

net-voip/yate/Manifest

@@ -1 +1,2 @@
 DIST yate-6.0.0-1.tar.gz 6039879 BLAKE2B d6d6398f7a91543c44435ab3cd73eaa1cca59c098c8b3ddbe66f5b058c45ab6cfc74533cc184235a44b499046331fa467961fc6fcd291418b24918d88f1037b9 SHA512 3a56bf5cd20c8452063f968de5d7993a926463b736686cd3df7a152d57be07fabeef9cebc91018ff0ad5b726157a9a9a0240969a752e7844f6431618b4eec53a
+DIST yate-6.1.0-1.tar.gz 6074737 BLAKE2B a59445b546730c1e9756e634c663f3ecc6875056ade1272afe9fc2a79c591515c7472b892a593df5c3001be6c822093fef0a16822b7537e477d064c06d849e03 SHA512 e23c9d45b98222cc4499833ef242e011b6d8c32213e9716958349bcbe74b1c168351b04ad9633073127d9463cda83c3236bd5640c0987cc14fd8f02349b4b293

net-voip/yate/yate-6.1.0.ebuild

@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="The Yate AV Suite"
+HOMEPAGE="http://yate.null.ro/"
+
+if [[ ${PV} == 9999 ]] ; then
+	ESVN_REPO_URI="http://voip.null.ro/svn/yate/trunk"
+	inherit subversion
+	KEYWORDS=""
+else
+	SRC_URI="http://voip.null.ro/tarballs/${PN}6/${P}-1.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="doc cpu_flags_x86_sse2 sctp dahdi zaptel wpcard tdmcard wanpipe +ilbc +ilbc-webrtc +isac-float isac-fixed postgres mysql +gsm +speex spandsp +ssl +zlib amrnb"
+
+RDEPEND="
+	postgres? ( dev-db/postgresql:* )
+	mysql? ( virtual/mysql )
+	gsm? ( media-sound/gsm )
+	speex? ( media-libs/speex )
+	ssl? ( dev-libs/openssl:0 )
+	zlib? ( sys-libs/zlib )
+	ilbc? ( dev-libs/ilbc-rfc3951 )
+	spandsp? ( >=media-libs/spandsp-0.0.3 )
+	dahdi? ( net-misc/dahdi )
+"
+DEPEND="doc? ( app-doc/doxygen )
+	virtual/pkgconfig
+	${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-6.0.0-dont-mess-with-cflags.patch )
+
+src_prepare() {
+	default_src_prepare
+	eautoreconf
+	./yate-config.sh || die
+}
+
+#fdsize, inline, rtti: keep default values
+#internalregex: use system
+#coredumper: not in the tree, bug 118716
+#wanpipe, wphwec: not in the tree, bug 188939
+#amrnb: not in tree!
+#zaptel: ??
+src_configure() {
+	econf \
+		--with-archlib=$(get_libdir) \
+		--without-libqt4 \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable sctp) \
+		$(use_enable dahdi) \
+		$(use_enable zaptel) \
+		$(use_enable wpcard) \
+		$(use_enable tdmcard) \
+		$(use_enable wanpipe) \
+		$(use_enable ilbc) \
+		$(use_enable ilbc-webrtc) \
+		$(use_enable isac-float) \
+		$(use_enable isac-fixed) \
+		$(use_with postgres libpq) \
+		$(use_with mysql) \
+		$(use_with gsm libgsm) \
+		$(use_with speex libspeex) \
+		$(use_with amrnb) \
+		$(use_with spandsp) \
+		$(use_with ssl openssl)
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	if use doc; then
+		emake DESTDIR="${ED}" install
+	else
+		emake DESTDIR="${ED}" install-noapi
+	fi
+	newinitd "${FILESDIR}"/yate.initd yate
+	newconfd "${FILESDIR}"/yate.confd yate
+}