media-gfx/graphicsmagick: Bump to version 1.3.26

Package-Manager: Portage-2.3.6, Repoman-2.3.2

media-gfx/graphicsmagick/Manifest

@@ -1 +1,2 @@
 DIST GraphicsMagick-1.3.25.tar.xz 5387880 SHA256 d64bfa52d2e0730eff9ce3ed51d4fc78dbb68e2adaa317b2bb3c56e6ee61ac9f SHA512 d62d6aee96d7b8444f1aa206b0c5cbbed9511612cb71d667af072ea52b68dcd11088699debc58faacbb014ad83fb8c2b3e474220f506069f7b5d22f0340f8ef8 WHIRLPOOL 8c2ffccf588495b78e0d84737e83ae396cbe86efa5dfddf6ec440626829d7b83f036771ec8be585dae58c3076eba8190ee809f0c09fc74c744efec96480a634b
+DIST GraphicsMagick-1.3.26.tar.xz 5400564 SHA256 fba015f3d5e5d5f17e57db663f1aa9d338e7b62f1d415b85d13ee366927e5f88 SHA512 b33ca0f1c858428693aee27a9089acff9e63d1110f85fa036894cfefe6274e7b2422758ea39852f94fdb4823c9c3f3c44b0d8906627503301f5928096f739f22 WHIRLPOOL 8c8874c34be6c921dfc5623352a04d2cf502f2b28aebad1f8d63c1067d5ffa7af6a22e9b9b7095bd98674ffc5c456434598145721431d1d5f7c7e68ab362e238

media-gfx/graphicsmagick/graphicsmagick-1.3.26.ebuild

@@ -0,0 +1,128 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools toolchain-funcs
+
+MY_P=${P/graphicsm/GraphicsM}
+
+DESCRIPTION="Collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.graphicsmagick.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="bzip2 cxx debug fpx imagemagick jbig jpeg jpeg2k lcms lzma modules openmp
+	perl png postscript q16 q32 static-libs svg test threads tiff truetype
+	webp wmf X zlib"
+
+RDEPEND="dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	fpx? ( media-libs/libfpx )
+	imagemagick? ( !media-gfx/imagemagick )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/jasper:= )
+	lcms? ( media-libs/lcms:2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl )
+	png? ( media-libs/libpng:0 )
+	postscript? ( app-text/ghostscript-gpl )
+	svg? ( dev-libs/libxml2 )
+	tiff? ( media-libs/tiff:0 )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libSM
+		x11-libs/libXext
+		)
+	zlib? ( sys-libs/zlib )"
+# corefonts are required because needed arial font (bug #588398).
+DEPEND="${RDEPEND}
+	test? ( media-fonts/corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.19-flags.patch
+	"${FILESDIR}"/${PN}-1.3.19-perl.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local depth=8
+	use q16 && depth=16
+	use q32 && depth=32
+
+	local openmp=disable
+	if use openmp && tc-has-openmp; then
+		openmp=enable
+	fi
+
+	econf \
+		--${openmp}-openmp \
+		--enable-largefile \
+		--enable-shared \
+		$(use_enable static-libs static) \
+		$(use_enable debug prof) \
+		$(use_enable debug gcov) \
+		$(use_enable imagemagick magick-compat) \
+		$(use_with threads) \
+		$(use_with modules) \
+		--with-quantum-depth=${depth} \
+		--without-frozenpaths \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options=INSTALLDIRS=vendor \
+		$(use_with bzip2 bzlib) \
+		$(use_with postscript dps) \
+		$(use_with fpx) \
+		--without-gslib \
+		$(use_with jbig) \
+		$(use_with webp) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k jp2) \
+		$(use_with lcms lcms2) \
+		$(use_with lzma) \
+		$(use_with png) \
+		$(use_with tiff) \
+		$(use_with truetype ttf) \
+		$(use_with wmf) \
+		--with-fontpath="${EPREFIX}"/usr/share/fonts \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts \
+		$(use_with svg xml) \
+		$(use_with zlib) \
+		$(use_with X x)
+}
+
+src_compile() {
+	default
+	use perl && emake perl-build
+}
+
+src_test() {
+	unset DISPLAY # some perl tests fail when DISPLAY is set
+	default
+}
+
+src_install() {
+	default
+
+	if use perl; then
+		emake -C PerlMagick DESTDIR="${D}" install
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
+}