app-emacs/org-mode: bump to 9.7.22

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
Maciej Barć
2025-02-16 23:35:16 +01:00
parent e5feb006f1
commit 5cfb2ecbae
2 changed files with 71 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST org-mode-release_9.7.19.tar.gz 2364122 BLAKE2B d7e65b8af54968a812e012aa11f380f64d65bd5e0829ecdc96d64a539c54f384157a336c192806d9fb32be50a0c6c62e60bc8d067ab581049b0edc8a57ad1327 SHA512 bef652cc8e31f86ccaf6ce0288389f1cb10aa43fd9d8f4191ab30e7d4563b977f4da309c322367a6f2beb27e88c3d771b5c4d4e259ca4c8c6a0b145c1e8d43ca
DIST org-mode-release_9.7.20.tar.gz 2364571 BLAKE2B 694e709b161a3669191fefa517b93d3629580cd986c48af0e0cf1198a1a7bcbee835c452ec87d4445f5ac91bf10f1127c8ad22283eede9b3eca5f67bed567f15 SHA512 ee81f6be7f544205c256811e90bd9dda9d830b1ad19dde079be7affbe304ee6ce6d059814f6658514af3273630ea3ce99797c6af419f0c9ab3f1f1b64e8bf35c
DIST org-mode-release_9.7.21.tar.gz 2364695 BLAKE2B 1cd3fe37ecfe4450dce69dd7499b6ddaaf5000edab26fd8f19ab5d09b1cf24aabf3c451d5c5e1f64f0d4436f8a60ce7ff2a28d7f97abf2af834c286fd81c70d3 SHA512 7309db82e95902e4e255e8f9f80095c2e7df80e8036b6aff39fbbe500aac4d8f6bfbaef3cacb67ed72a6ae9c44c90d36d2d59ceaef9f0d94228e0406276a392d
DIST org-mode-release_9.7.22.tar.gz 2364662 BLAKE2B 10a60b241fc87b141f3c6ea07bd99aae464fcf5bcaaf667c0a2340da85b711118d28059831a27d3eafacfedd1c7119162fdfb4cf19f42c9e46ac650d0afa56ce SHA512 7fb8f141315fa22ab5b87bcf16d104377b3309b1e25a88e93c5f088238112dfe726bd3b28d35530c0f1c7684c42967028e469b1767638ddff89bb891b6922d2f
+70
View File
@@ -0,0 +1,70 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit elisp readme.gentoo-r1
DESCRIPTION="An Emacs mode for notes and project planning"
HOMEPAGE="https://orgmode.org/"
if [[ "${PV}" == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}.git"
EGIT_CHECKOUT_DIR="${WORKDIR}/org"
S="${WORKDIR}/org"
else
MY_P="${PN}-release_${PV}"
SRC_URI="https://git.savannah.gnu.org/cgit/emacs/${PN}.git/snapshot/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
KEYWORDS="~amd64 ~ppc ~x86"
fi
LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
SLOT="0"
IUSE="doc odt-schema"
RESTRICT="test"
BDEPEND="
doc? ( virtual/texi2dvi )
"
SITEFILE="50${PN}-gentoo.el"
src_prepare() {
elisp_src_prepare
# Remove failing tests.
rm ./testing/lisp/test-{ob,ob-exp,ob-tangle,ob-shell}.el || die
}
src_compile() {
emake -j1 \
ORGVERSION="${PV}" \
datadir="${EPREFIX}${SITEETC}/${PN}"
use doc && emake -j1 pdf card
}
src_install() {
emake -j1 \
ORGVERSION="${PV}" \
DESTDIR="${D}" \
ETCDIRS="styles csl $(use odt-schema && echo schema)" \
lispdir="${EPREFIX}${SITELISP}/${PN}" \
datadir="${EPREFIX}${SITEETC}/${PN}" \
infodir="${EPREFIX}/usr/share/info" \
install
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
dodoc README.org CONTRIBUTE.org etc/ORG-NEWS
use doc && dodoc doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
so you may have to install one or more additional packages.
A non-exhaustive list of these dependencies may be found at
<http://orgmode.org/worg/org-dependencies.html>."
readme.gentoo_create_doc
}