dev-python/rq: Bump to 2.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2026-02-23 04:46:00 +01:00
parent 9fac512b0e
commit 5cea46ae57
2 changed files with 79 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST rq-2.6.1.tar.gz 675386 BLAKE2B e66a33618251e5fc8cd8a994c59ec1c0df194bbdb60a31dd5613b57097ffbbd4459069f82b56b26d335bd0e1ae8225a69e49c191c74ce37a04f6c77790a8114c SHA512 209fd3bf08999b41e057c23c15b2b5a7660e6d687ae7225a7ee8c7dd144fc69b67fe7c4be155ff6f8bba3c6ab95f38288055d7889630ca5bcace0e2c45da5fb3
DIST rq-2.7.0.tar.gz 679396 BLAKE2B b304624e88e6c2f636dc2bb69da845ffa12b40e27ac1a6198e56217233b61b3fee64c9c59e48388710408b43d6de6187881f8b6ed83ed04b783d848bd8fff234 SHA512 323a7b9f9d8ee2a74434d647db131c20d975f93215993c0410574f075fc5f6f340ebb4480c8acf8102944c13c0e699309baaf1a2b9a9f6a71367e0c772896ecb
+78
View File
@@ -0,0 +1,78 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( python3_{11..13} )
inherit distutils-r1 pypi
DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
HOMEPAGE="
https://python-rq.org/
https://github.com/rq/rq/
https://pypi.org/project/rq/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
RDEPEND="
>=dev-python/click-5.0[${PYTHON_USEDEP}]
dev-python/croniter[${PYTHON_USEDEP}]
>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-db/redis
dev-python/psutil[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=()
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# requires <sentry-sdk-2
tests/test_sentry.py::TestSentry::test_failure_capture
# hang
tests/test_commands.py::TestCommands::test_shutdown_command
tests/test_worker_pool.py::TestWorkerPool::test_check_workers
tests/test_worker_pool.py::TestWorkerPool::test_reap_workers
tests/test_dependencies.py::TestDependencies
# already present in older versions
tests/test_spawn_worker.py::TestWorker::test_work_and_quit
)
src_prepare() {
distutils-r1_src_prepare
# strip pin
sed -i -e '/dependencies/s:,!=[0-9.]*::' pyproject.toml || die
}
src_test() {
local -x TZ=UTC
local redis_pid="${T}"/redis.pid
local redis_port=6379
local redis_test_config="daemonize yes
pidfile ${redis_pid}
port ${redis_port}
bind 127.0.0.1
"
# Spawn Redis itself for testing purposes
# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
einfo "Spawning Redis"
einfo "NOTE: Port ${redis_port} must be free"
/usr/sbin/redis-server - <<< "${redis_test_config}" || die
# Run the actual tests
distutils-r1_src_test
# Clean up afterwards
kill "$(<"${redis_pid}")" || die
}