dev-util/sysdig: Bump to 0.16.0 w/ 4.11 kernel support

dev-util/sysdig/Manifest

@@ -3,3 +3,4 @@ DIST sysdig-0.13.0.tar.gz 678671 SHA256 2a5e744cef11348aa36d88bff9974557727e3b63
 DIST sysdig-0.14.0.tar.gz 682944 SHA256 e6a856fee9f7b00e3a46f176bf39fa737c20e684eeb38d34c1636684c3259e93 SHA512 b08ab671d58e41623003ecddc085da1e61133959578851208b9affc41d50a8163cd17e6beb7cc0c8833f435af9bd4b89565995d3a87920a8c2c1ce1530882f8d WHIRLPOOL 6e730237c590f0310b7cafc3e75c69fed7a996c91c71ec9b8b89e22f78456c6435925aa5e061473df3c29d5c2f5dd8d6ace5e6b659a81f26efefb087238590ac
 DIST sysdig-0.15.0.tar.gz 709358 SHA256 824bfd44c89d60e56a5a7a81a505ec91b6afcb3fd3962bf5697a9afe7ebe5723 SHA512 fe2ab11f5040a6c6970ec4fa1ac525141ca0b7f4a6908a9c9b6dca4807d3b8aeb7edc89ad10e6770a191cb4bccde97e67ef6ec97159a42d91d99a6d0cddef29c WHIRLPOOL 597ce8f47a17c43934c29d9df9c5ebec14729d980bbe5d2cf20a30545f51128f6282ecf41578a6c12a83693c29c77ae8130dd68220ecbc5830f2ccc359bc0de0
 DIST sysdig-0.15.1.tar.gz 712058 SHA256 4b404e15da9050742e62f3d65e0013fb497f84132ead4da61ba658c4f3d33a74 SHA512 49a66ef03468819d648c448c793587c0728443fa80e1bc392f1bdc46df70e5d90b2dfac488c5161b1ec8cc306632555b897c113062652239924f1a483b8d1cf2 WHIRLPOOL a1ef8c4dd89de288a04f4ec33d4978686480d7738f6961033d8f800e4dd2d2bf360b101f6d772772d4f71d4a7d2ad5e83b36c50aaea214f76784b061c482a1fa
+DIST sysdig-0.16.0.tar.gz 713245 SHA256 73a0190c973e4a591013d0c73ff2ea9f623ab50b78ff78f7a33fe31460ba24a1 SHA512 d8f3f0327ca1cd0fface433ccd41bf0919aba120bc2d01806806d0f3e88fa6982277d553ee9719f07d255495b946c765a156a5e69c03c0e830c510fc83def65e WHIRLPOOL e17ce8d22cada60f02db468a3103c54237482400c3bfe9a9833d3f5eb61953e910ddb8dbd642bc316c237d4b023da089624cd82f9879241ba5cd407fc60b649f

dev-util/sysdig/sysdig-0.16.0.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="http://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	dev-libs/openssl:0=
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${S}/driver:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+
+	if use modules; then
+		cmake-utils_src_make configure_driver
+
+		cp "${BUILD_DIR}"/driver/Makefile.dkms driver/Makefile || die
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}