media-video/oxine: depend on imagemagick-tools

Closes: https://bugs.gentoo.org/314343
Signed-off-by: Sam James <sam@gentoo.org>

media-video/oxine/oxine-0.7.1-r5.ebuild

@@ -1,7 +1,7 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
 inherit flag-o-matic
 
@@ -14,7 +14,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
 IUSE="curl debug dvb exif joystick jpeg lirc nls png v4l X"
 
-COMMON_DEPEND="
+DEPEND="
 	dev-libs/libcdio
 	media-libs/xine-lib[v4l?,X,imagemagick]
 	virtual/libcrypt:=
@@ -22,9 +22,9 @@ COMMON_DEPEND="
 	dvb? ( media-libs/xine-lib[v4l] )
 	joystick? ( media-libs/libjsw )
 	jpeg? (
-		media-gfx/imagemagick
 		media-libs/netpbm[jpeg,zlib(+)]
 		media-video/mjpegtools
+		virtual/imagemagick-tools[jpeg]
 	)
 	lirc? ( app-misc/lirc )
 	nls? (
@@ -32,52 +32,56 @@ COMMON_DEPEND="
 		sys-devel/gettext
 	)
 	png? (
-		media-gfx/imagemagick
 		media-libs/netpbm[png,zlib(+)]
 		media-video/mjpegtools
+		virtual/imagemagick-tools[png]
 	)
 	X? (
 		x11-libs/libXext
 		x11-libs/libX11
-	)"
-RDEPEND="${COMMON_DEPEND}
-	sys-apps/util-linux"
-DEPEND="${COMMON_DEPEND}
-	virtual/pkgconfig"
+	)
+"
+RDEPEND="
+	${DEPEND}
+	sys-apps/util-linux
+"
+BDEPEND="virtual/pkgconfig"
 
 HTML_DOCS=( doc/README.html )
 
 src_configure() {
 	# Fix underlinking by falling back to
-	# GNU89 inline semantics, bug 590946
+	# GNU89 inline semantics, bug #590946
 	append-cflags -std=gnu89
 
+	local myeconfargs=(
+		--disable-hal
+		--disable-rpath
+		--disable-extractor
+		$(use_with curl)
+		$(use_enable debug)
+		$(use_enable dvb)
+		$(use_enable exif)
+		$(use_enable joystick)
+		$(use_enable lirc)
+		$(use_enable nls)
+		$(use_enable v4l)
+		$(use_with X x)
+	)
+
 	# Note on images: Image support will be automatically disabled if
 	# netpbm, imagemagick or mjpegtools is not installed, regardless
 	# of what the USE flags are set to.
 	# If one of the image USE flags is unset, disable image support
-	local myconf=()
-	if use !png || use !jpeg; then
-		myconf+=( --disable-images )
+	if ! use png || ! use jpeg; then
+		myeconfargs+=( --disable-images )
 	fi
 
-	econf \
-		--disable-hal \
-		--disable-rpath \
-		--disable-extractor \
-		$(use_with curl) \
-		$(use_enable debug) \
-		$(use_enable dvb) \
-		$(use_enable exif) \
-		$(use_enable joystick) \
-		$(use_enable lirc) \
-		$(use_enable nls) \
-		$(use_enable v4l) \
-		$(use_with X x) \
-		"${myconf[@]}"
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
 }
 
 src_install() {
 	default
+
 	dodoc doc/keymapping.pdf
 }