net-firewall/conntrack-tools: Version 1.4.6

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
This commit is contained in:
Jeroen Roovers
2020-04-02 16:47:53 +02:00
parent 58f019f4f8
commit 5ca1d4ba99
2 changed files with 95 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST conntrack-tools-1.4.5.tar.bz2 479562 BLAKE2B 229531d1c6c237e539df5b83525dca5ce0b009a76a2a5f873282eabc73cc00095c15c686bc68f9364e81efc846bfa8eac8b08f7fd476199d10d0c25190ca2456 SHA512 480fe2cc4420bc8477a2ba67b3d052bcb39c6b3ec000cff27fc12db70b42ec94fa3b5fe12ee35d439e88d9a631a33cd12ae470b69dde6d371d4e53af62a2eed1
DIST conntrack-tools-1.4.6.tar.bz2 499806 BLAKE2B 7c1ee1c5fc2b6f9d33c6cf850eca80978b8763317b1a76892cefb776130564f15fbd4e4554fdb08dbba93d9f16b7e4624a1b4dd5a631f747f5fcc0a5b01b8d5e SHA512 a48260308a12b11b584fcf4658ec2c4c1adb2801c9cf9a73fc259e5c30d2fbe401aca21e931972413f03e415f98fbf9bd678d2126faa6c6d5748e8a652e58f1a
@@ -0,0 +1,94 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit linux-info
DESCRIPTION="Connection tracking userspace tools"
HOMEPAGE="http://conntrack-tools.netfilter.org"
SRC_URI="http://www.netfilter.org/projects/conntrack-tools/files/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~x86"
IUSE="doc +cthelper +cttimeout"
RDEPEND="
>=net-libs/libmnl-1.0.3
>=net-libs/libnetfilter_conntrack-1.0.8
>=net-libs/libnetfilter_queue-1.0.2
>=net-libs/libnfnetlink-1.0.1
net-libs/libtirpc
cthelper? (
>=net-libs/libnetfilter_cthelper-1.0.0
)
cttimeout? (
>=net-libs/libnetfilter_cttimeout-1.0.0
)
"
DEPEND="
${RDEPEND}
doc? (
app-text/docbook-xml-dtd:4.1.2
app-text/xmlto
)
virtual/pkgconfig
sys-devel/bison
sys-devel/flex
"
pkg_setup() {
linux-info_pkg_setup
if kernel_is lt 2 6 18 ; then
die "${PN} requires at least 2.6.18 kernel version"
fi
#netfilter core team has changed some option names with kernel 2.6.20
if kernel_is lt 2 6 20 ; then
CONFIG_CHECK="~IP_NF_CONNTRACK_NETLINK"
else
CONFIG_CHECK="~NF_CT_NETLINK"
fi
CONFIG_CHECK="${CONFIG_CHECK} ~NF_CONNTRACK
~NETFILTER_NETLINK ~NF_CONNTRACK_EVENTS"
check_extra_config
linux_config_exists || \
linux_chkconfig_present "NF_CONNTRACK_IPV4" || \
linux_chkconfig_present "NF_CONNTRACK_IPV6" || \
ewarn "CONFIG_NF_CONNTRACK_IPV4 or CONFIG_NF_CONNTRACK_IPV6 " \
"are not set when one at least should be."
}
src_prepare() {
# bug #474858
sed -i -e 's:/var/lock:/run/lock:' doc/stats/conntrackd.conf || die
default
}
src_configure() {
econf \
$(use_enable cthelper) \
$(use_enable cttimeout)
}
src_compile() {
default
use doc && emake -C doc/manual
}
src_install() {
default
newinitd "${FILESDIR}/conntrackd.initd-r3" conntrackd
newconfd "${FILESDIR}/conntrackd.confd-r2" conntrackd
insinto /etc/conntrackd
doins doc/stats/conntrackd.conf
dodoc -r doc/sync doc/stats AUTHORS TODO
use doc && dodoc doc/manual/${PN}.html
}