xfce-base/libxfce4ui: Bump to 4.17.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/libxfce4ui/Manifest

@@ -1,2 +1,3 @@
 DIST libxfce4ui-4.16.1.tar.bz2 785811 BLAKE2B d1267b328b7e2d07bfe85ce320da6a60d5a7d739c5ded9b213b83b0cde2061d3badc937e71c4353291ed435fb9d1294cadcc99402cdae69f4bcecf412dd525f2 SHA512 c183bbc75539c777fe704d0a1c4e533fdd2efb6cbc980cfedc2eaa80d0e6223db038498774ffcdc720d7f991dd8d9634183a757a4c4d1728cc9956a33cb187d0
 DIST libxfce4ui-4.17.1.tar.bz2 805413 BLAKE2B 008ab4988e66bc4f3dff3a9071ff1bcb83b7100193a5b10bec123a3c55ae94a21e43cb1bbf9723d5b736bede32f96425ff3e1768f43d607142d0b42ece5ddf29 SHA512 4ec6da3c454752c024e8ca26a84e6524d5fc12644a36c77a77375d533faf8f971d95dec555db7441ec100a17dd9fffd094144226efe27a155490a7c2bdea6484
+DIST libxfce4ui-4.17.2.tar.bz2 887332 BLAKE2B bc87ffe478350dc4c11fd9474e71c9d4d2603297dcc78f0f7232327247b552be927ab94023fdd8c4b6df0040b8db0e8417cc13920177d8c3cedc34942cc385ca SHA512 49465366ce29df072ae52414197720d9df774c13fcc7eff3dca2a065f2132980726bdb019dfe476dcfb40ff27d227d23e0814fbf40ef62a044faf3b873ded6e6

xfce-base/libxfce4ui/libxfce4ui-4.17.2.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade +introspection startup-notification system-info vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3[introspection?,X]
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=xfce-base/libxfce4util-4.15.6:=[introspection?]
+	>=xfce-base/xfconf-4.12:=
+	glade? ( dev-util/glade:3.10 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	startup-notification? ( x11-libs/startup-notification )
+	system-info? (
+		dev-libs/libgudev
+		gnome-base/libgtop
+		>=media-libs/libepoxy-1.2
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable system-info glibtop)
+		$(use_enable system-info epoxy)
+		$(use_enable system-info gudev)
+		$(use_enable startup-notification)
+		$(use_enable vala)
+		$(use_enable glade gladeui2)
+		--with-vendor-info=Gentoo
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}