app-containers/container-libs: update to 0.69.0

Signed-off-by: Rahil Bhimjiani <me@rahil.rocks>
Part-of: https://github.com/gentoo/gentoo/pull/46630
Closes: https://github.com/gentoo/gentoo/pull/46630
Signed-off-by: Zac Medico <zmedico@gentoo.org>

app-containers/container-libs/Manifest

@@ -1 +1,2 @@
 DIST container-libs-0.68.0.tar.gz 13304245 BLAKE2B 73a578c45cd2fcf5d1481a17406c2b15472d2ae51d34154e847750fc32a5a8b6631404ef2bd261dec1d35a65fbe8b38d0d0053c6d1b0ecf31197025955d16173 SHA512 2725689c41904886c22de3d70a0fdcc93f36e588f2a49970d5ad94dfbcc2029581c3ef824ca7f9f01a52935a9703e41fa184132c61e1daac3f221966326bea40
+DIST container-libs-0.69.0.tar.gz 13694913 BLAKE2B 85c79693473d67f1d6fddb2f9aa1c4b8e10863f28e4cf83d9d467cf69c306fcac3b444d4aaabb312ce694dd71581ff2ce17c4d2ff9c9c133932826f69eb00a39 SHA512 db2a199a702291b035826c0a27eacdfe2aa6d8a75de52d1c4c76718b1843b5960980ad9735d5d9e18f7f5ca0a5159a54316e8c74f0f17395ef94fd59f43dcaa6

app-containers/container-libs/container-libs-0.69.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+inherit readme.gentoo-r1
+
+DESCRIPTION="Several utilities from the containers project"
+HOMEPAGE="https://github.com/podman-container-tools/container-libs"
+SRC_URI="https://github.com/podman-container-tools/container-libs/archive/common/v${PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${PN}-common-v${PV}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~riscv"
+IUSE="+extra"
+RESTRICT="test"
+
+RDEPEND="
+	app-containers/containers-shortnames
+	>=sys-fs/fuse-overlayfs-1.16
+	extra? (
+		>=app-containers/crun-1.25.1
+		>=app-containers/netavark-2.0.0
+		>=net-misc/passt-2026.05.26
+	)
+	!app-containers/containers-image
+	!app-containers/containers-common
+	!app-containers/containers-storage
+	!<app-containers/buildah-1.44.0
+	!<app-containers/podman-6.0.0
+	!<app-containers/skopeo-1.23
+"
+DEPEND="${RDEPEND}"
+BDEPEND=">=dev-go/go-md2man-2.0.7"
+PATCHES=(
+	"${FILESDIR}"/c-libs-0.68.0-remove-go-cc.patch
+)
+
+DOC_CONTENTS="
+For rootless operations, one needs to configure subuid(5) and subgid(5).
+See /etc/sub{uid,gid} to check whether rootless user is already configured.
+If not, quickly configure it with:\n
+usermod --add-subuids 1065536-1131071 <rootless user>\n
+usermod --add-subgids 1065536-1131071 <rootless user>
+"
+
+src_compile() {
+	emake -C common PREFIX="${EPREFIX}/usr" docs
+	emake -C image docs
+	emake -C storage docs
+	touch {images,layers}.lock || die
+}
+
+src_install() {
+	emake -C common DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+	emake -C image DESTDIR="${ED}" install
+	emake -C storage DESTDIR="${ED}" install
+	readme.gentoo_create_doc
+
+	insinto /usr/share/containers
+	doins common/pkg/{seccomp/seccomp.json,subscriptions/mounts.conf} storage/storage.conf image/registries.conf
+
+	keepdir /etc/containers/{certs.d,oci/hooks.d,networks,systemd,registries.conf.d,registries.d} \
+			/var/lib/containers/sigstore /usr/share/containers/systemd
+
+	diropts -m0700
+	dodir /usr/lib/containers/storage/overlay-{images,layers}
+	local i
+	for i in images layers; do
+		insinto /usr/lib/containers/storage/overlay-"${i}"
+		doins "${i}".lock
+	done
+	insinto /usr/share/containers/registries.conf.d
+	newins "${FILESDIR}/c-libs-0.68.0-registries.conf" 00-gentoo.conf
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}