gnome-extra/gucharmap: add 17.0.1

Signed-off-by: Vladislav Mikhailikov <vmikhailikov@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/45280
Closes: https://github.com/gentoo/gentoo/pull/45280
Signed-off-by: Sam James <sam@gentoo.org>

gnome-extra/gucharmap/Manifest

@@ -1 +1,2 @@
 DIST gucharmap-16.0.1.tar.bz2 1503713 BLAKE2B e77b0d9e12d73f38b8e32c078bed3be2e7a1a3c3d61578e79f539209f7af0106dca1b8201610c512ccc100bb2a239f57c097dd96f78c1959d64e67e7cf47345e SHA512 9816e6fda5c7a8ce34af41c55121e1291e07033a636955d3501c4eb57e290ca5e9ef74d7e622e3be1c85140fc55d4d21012a84c2a3bf3effc195bdb38740241b
+DIST gucharmap-17.0.1.tar.xz 1392876 BLAKE2B 6cb33a8a9e37686c047a62cf4912b87fe7234e2532f23df9d5560fa90325f404104cd6a999578e3995f308da69c935005b910f4ab08a3d55885bcb66f92a752a SHA512 222e5073af5c0266b0defffe06cb5077fecd779428efcc1bd9626a724420ee51650fd5c8b1e67f1b5aa2b34d9bdb9b08139cb5726818af31cbc23635e244e3a6

gnome-extra/gucharmap/gucharmap-17.0.1.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit flag-o-matic gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Unicode character map viewer and library"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gucharmap"
+
+LICENSE="GPL-3+"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+UNICODE_VERSION="17.0.0"
+
+IUSE="+introspection gtk-doc vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="media-libs/freetype:2
+	>=dev-libs/glib-2.32:2[introspection?]
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=dev-libs/libpcre2-10.21:=
+	=app-i18n/unicode-data-${UNICODE_VERSION}*
+	>=x11-libs/pango-1.42.4-r2[introspection?]
+	>=x11-libs/cairo-1.16
+	>=app-accessibility/at-spi2-core-2.56.5:2[introspection?]
+
+	!gnome-extra/gucharmap:0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	app-text/docbook-xml-dtd:4.1.2
+	dev-libs/glib:2
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( >=dev-util/gtk-doc-1 )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}"/14.0.1-install-user-help.patch
+)
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	# Upstream don't support LTO & error out on it in meson.build (bug #926250)
+	filter-lto
+
+	local emesonargs=(
+		-Dcharmap=true
+		-Ddbg=false # in 14.0.1 all this does is pass -ggdb3
+		$(meson_use gtk-doc docs)
+		$(meson_use introspection gir)
+		-Dgtk3=true
+		-Ducd_path="${EPREFIX}/usr/share/unicode-data"
+		$(meson_use vala vapi)
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}