app-misc/anki: update EAPI 7 -> 8, enable py3.11, fix prefs

Thanks to WGH for the backport of the pref fix.

Closes: https://bugs.gentoo.org/869917
Closes: https://bugs.gentoo.org/896566
Signed-off-by: Sam James <sam@gentoo.org>

app-misc/anki/anki-2.1.15-r2.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit desktop optfeature python-single-r1 xdg
+
+DESCRIPTION="A spaced-repetition memory training program (flash cards)"
+HOMEPAGE="https://apps.ankiweb.net"
+SRC_URI="https://apps.ankiweb.net/downloads/archive/${P}-source.tgz -> ${P}.tgz"
+
+LICENSE="AGPL-3+ BSD MIT GPL-3+ CC-BY-SA-3.0 Apache-2.0 CC-BY-2.5"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		>=dev-python/PyQt5-5.12[gui,svg,widgets,${PYTHON_USEDEP}]
+		>=dev-python/PyQtWebEngine-5.12[${PYTHON_USEDEP}]
+		>=dev-python/httplib2-0.7.4[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/markdown[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/send2trash[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="test? (
+	${RDEPEND}
+	$(python_gen_cond_dep '
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch
+	"${FILESDIR}"/${PN}-2.1.15-mpv-args.patch
+	"${FILESDIR}"/${PN}-2.1.15-unescape.patch
+	"${FILESDIR}"/${PN}-2.1.15-fix-prefs.patch
+)
+
+src_prepare() {
+	default
+	sed -i -e "s/updates=True/updates=False/" \
+		aqt/profiles.py || die
+}
+
+src_compile() {
+	:;
+}
+
+src_test() {
+	sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${BROOT}/usr/bin/nosetests\":" \
+		-i tools/tests.sh || die
+	sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${BROOT}/usr/bin/nosetests3\":" \
+		-i tools/tests.sh || die
+	sed -e "s:which nosetests3:which ${BROOT}/usr/bin/nosetests3:" \
+		-i tools/tests.sh || die
+	./tools/tests.sh || die
+}
+
+src_install() {
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+	doman ${PN}.1
+
+	dodoc README.md README.development
+	python_domodule aqt anki
+	python_newscript runanki anki
+
+	# Localization files go into the anki directory:
+	python_moduleinto anki
+	python_domodule locale
+
+	# not sure if this is correct, but
+	# site-packages/aqt/mediasrv.py wants the directory
+	insinto /usr/share/anki
+	doins -r web
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "LaTeX in cards" "app-text/texlive app-text/dvipng"
+	optfeature "Record sound" "dev-python/pyaudio media-sound/lame"
+	optfeature "Playback sound" media-video/mpv media-video/mplayer
+}

app-misc/anki/files/anki-2.1.15-fix-prefs.patch

@@ -0,0 +1,17 @@
+https://bugs.gentoo.org/869917#c3
+https://github.com/ankitects/anki/commit/d2ae874d9e1615d09afc912275cc3b27776a1392
+
+--- a/aqt/preferences.py
++++ b/aqt/preferences.py
+@@ -77,8 +77,8 @@ class Preferences(QDialog):
+             f.hwAccel.setVisible(False)
+         else:
+             f.hwAccel.setChecked(self.mw.pm.glMode() != "software")
+-        f.lrnCutoff.setValue(qc['collapseTime']/60.0)
+-        f.timeLimit.setValue(qc['timeLim']/60.0)
++        f.lrnCutoff.setValue(int(qc['collapseTime']/60.0))
++        f.timeLimit.setValue(int(qc['timeLim']/60.0))
+         f.showEstimates.setChecked(qc['estTimes'])
+         f.showProgress.setChecked(qc['dueCounts'])
+         f.nightMode.setChecked(qc.get("nightMode", False))
+