dev-python/zope-configuration: Bump to 6.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/zope-configuration/Manifest

@@ -1 +1,2 @@
 DIST zope.configuration-5.0.1.tar.gz 83327 BLAKE2B 665687d49e77c43e08293d5e7816a1f1abc9ff0c97dcfa83a90693d6da9d5767ebc24512dd7593316464103c38655c41909949bb1c8bb3f5db272e3637066284 SHA512 58fec7b330a4ee5f9bb71238fbcb8f07fdd7b6767cb2d8e054699ffcb915973b9dfead33e5515f40049f6aede233d31624d09d7f84d75b96318e63f8ab454147
+DIST zope_configuration-6.0.tar.gz 84258 BLAKE2B f0e0b918125a24b0a4ac8679c3a02e4c01b44a013c7b33a778577b4cad54c2426eaab8a572cf3cc8a92e034d88658200a9787e007712bf04e1968aa9ed2ba627 SHA512 2dd86fe8beaf1b15dc7d96ce5b037c530cc3e4427c6e2152741e6697a84b90dd06f65d0d0968d938dccdded278d8b0bbfe924abedf772f1110ef039ee3eb5f8a

dev-python/zope-configuration/zope-configuration-6.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Zope Configuration Architecture"
+HOMEPAGE="
+	https://pypi.org/project/zope.configuration/
+	https://github.com/zopefoundation/zope.configuration/
+	https://zopeconfiguration.readthedocs.io/en/latest/
+"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/zope-i18nmessageid[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	>=dev-python/zope-schema-4.9[${PYTHON_USEDEP}]
+	!dev-python/namespace-zope
+"
+BDEPEND="
+	test? (
+		dev-python/manuel[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}