dev-python/pyshark: bump to 0.3.7.2

Use github tarball for tests.

Package-Manager: Portage-2.3.5_p31, Repoman-2.3.2_p61

dev-python/pyshark/Manifest

@@ -1 +1,2 @@
 DIST pyshark-0.3.6.tar.gz 15237 SHA256 51372c0a36446af45f0101d4fc97b336a096356c28da6626041889bf3b24c6f2 SHA512 e2250af229f072f32fa7900dbafbc29b5964134dd7849b53729afb220a5a20faa3b48515d1b83f0084a6f251187b00c192ce5b16e276faf784404bfe5b9c1fa5 WHIRLPOOL 0e77ac977818e61386ac47a64bb31da138c5a2736768a7806d638745c547bf58b777060cc1958af9af40a28ebf20e89f67b4cf292588ebd5b3aec5f30fe10e26
+DIST pyshark-0.3.7.2.tar.gz 27232 SHA256 a60bee95e5359c11f2051ebbb240c41becfa8c1ffe03b2fb24895f477bb1c0fe SHA512 dbd97665fae7d3067582bf7616e025b0c5e5fa14cacdaca59c89b4e70feb3017f2d8c7d899a70c0c8707589e4735b9283914bb6ccbf432e9072c64d7e957bc15 WHIRLPOOL 9e6f58dc6a4e2acf77f016b35583da427ccfc8ed32d508e3e7b754913f9e8f6dce2c48be5adf1c2fa56fabecd99f18e1a678dace1c1423be132bcbdbbb85effd

dev-python/pyshark/pyshark-0.3.7.2.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="A Python wrapper for tshark output parsing"
+HOMEPAGE="https://pypi.python.org/pypi/pyshark https://github.com/KimiNewt/pyshark"
+# pypi tarball is missing tests
+#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+SRC_URI="https://github.com/KimiNewt/pyshark/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# See pyshark.egg-info/requires.txt
+RDEPEND="
+	dev-python/py[${PYTHON_USEDEP}]
+	dev-python/logbook[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/trollius[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+	net-analyzer/wireshark"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${P}/src"
+
+python_prepare_all() {
+	# Test fails in ebuild env, works standalone.
+	rm "${WORKDIR}/${P}/tests/capture/test_inmem_capture.py" || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${WORKDIR}/${P}/tests" || die
+	py.test -v || die
+}