mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 18:47:16 -08:00
net-misc/dropbox: bump to 134
Package-Manager: Portage-3.0.28, Repoman-3.0.3 Signed-off-by: Ben Kohler <bkohler@gentoo.org>
This commit is contained in:
@@ -1,2 +1,4 @@
|
||||
DIST dropbox-lnx.x86-133.4.4089.tar.gz 99659191 BLAKE2B d13af3f0ff0f763773969292470165c2e0695a1341bf78f69227048f245bcbd0cd520f748c40062661e9c1a95bf290fb3ff72d5d960fa86db03c70e7892d36d7 SHA512 716e9c387c19424e75b8fa164ce978ed9cfb0b5a26ff425162183293c26a6a09e33e76432f9f6badd5fb6d80ae658cb310d69345cb74861df474f3628a2023bc
|
||||
DIST dropbox-lnx.x86-134.4.4115.tar.gz 99756969 BLAKE2B cb8a753725a35c490ab13aec82e529b3bf9027c721f2d1eba5c6974c27e4e39054f9a8186d948eeb6b2dd216a0bcd252fe26c7c7053c80da5e69a623a73de344 SHA512 93db18ee248198b6ff8ff42f10dd8c151c9f38225f8f2d2c14e0240ce4a1fcc205458db7bc8877a46c97524a3db922c81c05de2b93edc20f0f5d96e33f5571f2
|
||||
DIST dropbox-lnx.x86_64-133.4.4089.tar.gz 101463037 BLAKE2B 561efbfa7adb5b173112d36e63e92c31bbc6e4cdc87671817222c55c5b3beebe0195d8f566e0da6a1196ecd75f6148a6307ebd998c77b41760b0596f3fae8e70 SHA512 8b7509d813653478ecf86addb00f8b8f2739976e716c94a67f5f471396a656c43cafab9104722bd238e42965d3ef34cc6273aa92af5a0ea9076da0a5fb40b1c2
|
||||
DIST dropbox-lnx.x86_64-134.4.4115.tar.gz 101575017 BLAKE2B 46d9124cac8c318dbefe3d1579dfeffa4b1cf48ea173a9635af243a2a26f340ce8fdcedcc8efb61316e89407f9fb96d1166c3cea5d2f86a7321b33cd4d58a4ed SHA512 2593caa766fddf88a85cd218e99c013ef071d8aeac1b37f16c65d25769014cfcec0ad3158f2bfb19b79d88e4f1e1ef5937f281c2a735c55c3bac5a930553096c
|
||||
|
||||
@@ -0,0 +1,105 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit desktop pax-utils systemd xdg
|
||||
|
||||
DESCRIPTION="Dropbox daemon (pretends to be GUI-less)"
|
||||
HOMEPAGE="https://www.dropbox.com/"
|
||||
SRC_URI="
|
||||
amd64? ( https://clientupdates.dropboxstatic.com/dbx-releng/client/dropbox-lnx.x86_64-${PV}.tar.gz )
|
||||
x86? ( https://clientupdates.dropboxstatic.com/dbx-releng/client/dropbox-lnx.x86-${PV}.tar.gz )"
|
||||
|
||||
LICENSE="BSD-2 CC-BY-ND-3.0 FTL MIT LGPL-2 openssl dropbox"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86 ~x86-linux"
|
||||
IUSE="selinux X"
|
||||
|
||||
RESTRICT="mirror strip"
|
||||
|
||||
QA_PREBUILT="opt/.*"
|
||||
QA_EXECSTACK="opt/dropbox/dropbox"
|
||||
|
||||
BDEPEND="dev-util/patchelf"
|
||||
|
||||
# Be sure to have GLIBCXX_3.4.9, #393125
|
||||
RDEPEND="
|
||||
X? (
|
||||
x11-themes/hicolor-icon-theme
|
||||
)
|
||||
selinux? ( sec-policy/selinux-dropbox )
|
||||
app-arch/bzip2
|
||||
dev-libs/glib:2
|
||||
dev-libs/libffi-compat:6
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
net-misc/wget
|
||||
sys-libs/zlib
|
||||
sys-libs/ncurses-compat:5
|
||||
virtual/opengl
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libX11
|
||||
x11-libs/libXext
|
||||
x11-libs/libXrender
|
||||
x11-libs/libxcb
|
||||
"
|
||||
|
||||
src_unpack() {
|
||||
unpack ${A}
|
||||
mkdir -p "${S}" || die
|
||||
mv "${WORKDIR}"/.dropbox-dist/* "${S}" || die
|
||||
mv "${S}"/dropbox-lnx.*-${PV}/* "${S}" || die
|
||||
rmdir "${S}"/dropbox-lnx.*-${PV}/ || die
|
||||
rmdir .dropbox-dist || die
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
# we supply all of these in RDEPEND
|
||||
rm -vf libGL.so.1 libX11* libffi.so.6 || die
|
||||
# some of these do not appear to be used
|
||||
rm -vf libQt5{OpenGL,PrintSupport,Qml,Quick,Sql,WebKit,WebKitWidgets}.so.5 \
|
||||
PyQt5.QtPrintSupport.* PyQt5.QtQml.* PyQt5.QtQuick.* \
|
||||
wmctrl libdrm.so.2 libpopt.so.0 || die
|
||||
if use X ; then
|
||||
mv images/hicolor/16x16/status "${T}" || die
|
||||
else
|
||||
rm -vrf images || die
|
||||
fi
|
||||
patchelf --set-rpath '$ORIGIN' \
|
||||
apex._apex.*.so \
|
||||
nucleus_python.*.so \
|
||||
tprt.*.so \
|
||||
|| die
|
||||
pax-mark cm dropbox
|
||||
mv README ACKNOWLEDGEMENTS "${T}" || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local targetdir="/opt/dropbox"
|
||||
|
||||
insinto "${targetdir}"
|
||||
doins -r *
|
||||
fperms a+x "${targetdir}"/{dropbox,dropboxd}
|
||||
dosym "${targetdir}/dropboxd" "/opt/bin/dropbox"
|
||||
|
||||
use X && doicon -s 16 -c status "${T}"/status
|
||||
|
||||
make_desktop_entry "${PN}" "Dropbox" "dropboxstatus-logo"
|
||||
|
||||
newinitd "${FILESDIR}"/dropbox.initd dropbox
|
||||
newconfd "${FILESDIR}"/dropbox.conf dropbox
|
||||
systemd_newunit "${FILESDIR}"/dropbox_at.service-r2 "dropbox@.service"
|
||||
|
||||
dodoc "${T}"/{README,ACKNOWLEDGEMENTS}
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
einfo "Warning: while running, dropbox may attempt to autoupdate itself in"
|
||||
einfo " your user's home directory. To prevent this, run the following as"
|
||||
einfo " each user who will run dropbox:"
|
||||
einfo ""
|
||||
einfo "install -dm0 ~/.dropbox-dist"
|
||||
}
|
||||
Reference in New Issue
Block a user