media-sound/picard: bump to 2.7

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

media-sound/picard/Manifest

@@ -1 +1,2 @@
 DIST picard-2.6.4.tar.gz 4319362 BLAKE2B 78768b4a8a22c51c118ba03a9e97ba6c4bec9180e5739867b5756170083930a942a0a1ceaeb74bbe724af3ca392b92139cbc4acdde9556e9031be16a968a0240 SHA512 5f44f91f9f44cb17ecd27e204b75c83b776a2c55e2a6e42f96018c83f4073d92f028ef74006d6acbe42b1ed374543a65e177f34c561bfdf13ded1085515bf353
+DIST picard-2.7.tar.gz 4868049 BLAKE2B 87f04056843623f81165bdae181699125d5aa8e41e5da47d645026bb1b3ee4a70edeeef0399f3230584026caf8f014cfe27b5d9f3f2e6b71a8e2de48a832655a SHA512 b88d2cc24a9b6a01e6bb1a54f93bb8ec62c901fe9ff352641ea402b5e091d71241665b067fd12bbf77cf219b951db9a570400adda82fa9da9406f9cfa6aee4e5

media-sound/picard/picard-2.7.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/metabrainz/picard"
+	inherit git-r3
+else
+	SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-release-${PV}"
+fi
+
+DESCRIPTION="Cross-platform music tagger"
+HOMEPAGE="https://picard.musicbrainz.org"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="discid fingerprints nls"
+
+BDEPEND="
+	nls? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/fasteners[${PYTHON_USEDEP}]
+		dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		media-libs/mutagen[${PYTHON_USEDEP}]
+		discid? ( dev-python/python-discid[${PYTHON_USEDEP}] )
+	')
+	fingerprints? ( media-libs/chromaprint[tools] )
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local build_args=(
+		--disable-autoupdate
+	)
+	if ! use nls; then
+		build_args+=( --disable-locales )
+	fi
+	distutils-r1_python_compile ${build_args[@]}
+}
+
+python_install() {
+	local install_args=(
+		--disable-autoupdate
+		--skip-build
+	)
+	if ! use nls; then
+		install_args+=( --disable-locales )
+	fi
+	distutils-r1_python_install ${install_args[@]}
+}