dev-python/ipyparallel: Bump to 9.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/ipyparallel/Manifest

@@ -1,2 +1,4 @@
 DIST ipyparallel-9.0.2.tar.gz 4407304 BLAKE2B 4095b9eb9f61a3d3da311ddfa01a3c185d99d44d9cd51079e40422dfa6b1c6522d34f5df7254f3ba19622da8aeec5b3b16c86fb43ce94f9173a00bf4b53ca1fc SHA512 c7719a9313a3bdf40300a09888f056884cbcf77158fec1eef4cd242ce956e2b6fa1917b35c1997d0b375dc8e590212c6c23f533c1a20673c59eaf411fbded7bf
 DIST ipyparallel-9.0.2.tar.gz.provenance 9373 BLAKE2B 5c842b77ad12f4deab211325146d592c62663f4e05a77c97e39f4331362614a938262f38b284a6968abd0a61bca681c08414a0f92ec86452e10673a93713a77b SHA512 80d7e8268fcee7f2d8fa676dd82be45df90c7f22710563f2a246ae365a04c23a5bfc26a5181369243919202f311833278a23c86c0f356432f0bf9f211859544f
+DIST ipyparallel-9.1.0.tar.gz 4427086 BLAKE2B f219325a7ce0a4ac4f0d215cfa9fac2431074b663fbc3ac316b30031f145ae8291598f54a0bdc923f43d70d65482f65ebc3a51c52b49e627f7ea676a31cda556 SHA512 f62689a5991e7d923d796a1a2caf03c7f0ed4ffc41f70d77002aac9ae24be67b2268e386b3652819c3826beb94b245593874564b707251efdcf4ebe4a9293706
+DIST ipyparallel-9.1.0.tar.gz.provenance 9517 BLAKE2B 09a65b092c7241a9812a4c0912e555f637b4b95a6f6fba9d4e958ba35aef7effa0845ec72b3a22d9bd1b07cddd1a93cf89eef2bb20a3c874100b297e2f997551 SHA512 05da5c203eaf715b37d0310a8ce52edd53ad7ceb891056387aebdd8cf1461e72e6b170ded87225370744dd2dceadf8389b512a87217fe2f72ac811c35939c03a

dev-python/ipyparallel/ipyparallel-9.1.0.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/ipython/ipyparallel
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Interactive Parallel Computing with IPython"
+HOMEPAGE="
+	https://ipyparallel.readthedocs.io/
+	https://github.com/ipython/ipyparallel/
+	https://pypi.org/project/ipyparallel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-25[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5[${PYTHON_USEDEP}]
+	>=dev-python/ipython-5[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7[${PYTHON_USEDEP}]
+	dev-python/jupyter-server[${PYTHON_USEDEP}]
+	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.9.1[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/flit-core[${PYTHON_USEDEP}]
+	test? (
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+# TODO: package myst_parser
+# distutils_enable_sphinx docs/source
+EPYTEST_PLUGINS=( pytest-asyncio )
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# we don't run a mongo instance for tests
+	ipyparallel/tests/test_mongodb.py::TestMongoBackend
+	# TODO
+	ipyparallel/tests/test_util.py::test_disambiguate_ip
+	# Gets upset that a timeout _doesn't_ occur, presumably because
+	# we're cranking up too many test timeouts. Oh well.
+	# bug #823458#c3
+	ipyparallel/tests/test_asyncresult.py::AsyncResultTest::test_wait_for_send
+	# We could patch the timeout for these too but they're going to be inherently
+	# fragile anyway based on what they do.
+	ipyparallel/tests/test_client.py::TestClient::test_activate
+	ipyparallel/tests/test_client.py::TestClient::test_lazy_all_targets
+	ipyparallel/tests/test_client.py::TestClient::test_wait_for_engines
+)
+
+src_configure() {
+	export IPP_DISABLE_JS=1
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# move /usr/etc stuff to /etc
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	optfeature "Jupyter Notebook integration" dev-python/notebook
+}