dev-python/ipykernel: add 6.15.2

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/ipykernel/Manifest

@@ -1 +1,2 @@
 DIST ipykernel-6.15.1.tar.gz 133140 BLAKE2B 7d63b55f2b8d883234258106b8239cf77031336ce6e7e38234490a031fc4a56861788210fdb2acd0f895e4df43257b0339ef1592e12d33b441e4ba9061acbd08 SHA512 10f2390a4edafea89fcc049d5e07ef542418a3a7b076efec1f02bc0a787e01280624cc543bb60604478cae63b58a86d031b549a6f872c7a8530043d670dbdc0e
+DIST ipykernel-6.15.2.tar.gz 133297 BLAKE2B 05b92074dba2324a2bbbe58fb459f455e47236fcbed711b63c3bfd83978b1e80a7fe079c08fbfb031d9f182d2b24a265705f6540b6c87ee933b641beaee53f9d SHA512 14f1f819d67f16e9c5ea5705ce9c1827bd1ae44f742ca809c4402ef64b229e902f9a724c0609cbf225da595f4ed48cd14348f3c887d70bc18c4b017ec01de720

dev-python/ipykernel/ipykernel-6.15.2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="https://github.com/ipython/ipykernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.0[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/inprocess/tests/test_kernel.py::InProcessKernelTestCase::test_pylab
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}