www-client/falkon: 26.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

www-client/falkon/Manifest

@@ -1,2 +1,3 @@
 DIST falkon-26.04.1.tar.xz 2712204 BLAKE2B ffad1da9db0814ff2e4b4a7a59ddba07eb8c94d2b11d156da4c8c3761205f4f686838d29f77245811176a753ec4f2aef6cbd30b2b86ad0a4c82804e55a795d10 SHA512 8bf416017da23bbeb436913177ff0d15ec47f8995ab2248a81fcf67aab0e306c4857324f709a21a87521b57087157af03df877640b881b527411e086b9527cf6
 DIST falkon-26.04.2.tar.xz 2712068 BLAKE2B bac8944d64ee66abc8dd2fde2a561e1277cb95632c29d86607b80135ad568e62b1babbb3211d4c2d6b4ce6cb2a5e058f9b8f3efa7f19d613df6137fa594e061e SHA512 fc220b79321ac52be290f7732267f94eb89f459c3f69e90c55b4f7a2356665db6a4fe5a6f824a1b7d65ce5c775f87c0cd67e5d647c5af7b74cfef4fec9fd64ce
+DIST falkon-26.04.3.tar.xz 2733088 BLAKE2B eb77e2b0643285a7ac8e326c2d230d4fc2cb79cc42e3ca172553143a420af82467c34fe46b88c14e996bad76a4ee0222144716a7c3fe77fac3a2c18735bfbc0f SHA512 d741386e6a321587d96a224441418af0297c31a9f821eaf83149217f145bcee1373b828195b59e5e2b9ee1f46e2a8672db5eff335df192fa48ca0646bb0bdf33

www-client/falkon/falkon-26.04.3.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.22.0
+QTMIN=6.10.1
+PYTHON_COMPAT=( python3_{11..14} )
+inherit ecm gear.kde.org python-single-r1 xdg
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui,network,sql,sqlite,ssl,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtwebchannel-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6=[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	virtual/libintl
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:6
+		>=kde-frameworks/kcrash-${KFMIN}:6
+		>=kde-frameworks/kio-${KFMIN}:6
+		>=kde-frameworks/kjobwidgets-${KFMIN}:6
+		>=kde-frameworks/kwallet-${KFMIN}:6
+		>=kde-frameworks/purpose-${KFMIN}:6
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside-${QTMIN}:6[gui,positioning,uitools(-),webengine,widgets,\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:6"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:6
+"
+BDEPEND=">=dev-qt/qttools-${QTMIN}:6[linguist]"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF6Wallet)
+		$(cmake_use_find_package kde KF6KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}