gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-24 18:58:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/scikit-build: Bump to 0.16.2

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-11-05 12:22:27 +01:00
parent 09453aaf12
commit 58d37ccfb9
2 changed files with 73 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/scikit-build/Manifest
View File

@@ -1,2 +1,3 @@
DIST scikit-build-0.15.0.tar.gz 268691 BLAKE2B f4cb51ee2367bd4ba6f6c1cada15e1e6be731998a914b28edcf703c5a92c409b78b17dddf04a29b24d40f249ffa06eb9d05d36dc30c0e62ee001519c3ca03f58 SHA512 4d9b1d06d48708ff4f2f5fa8c8f264c7ca85946d5842a1254930d9449d6b6386c17392473c3c85147f6573f7256c94c927962cb56fa23a90a5b442de8de8d727
DIST scikit-build-0.16.1.tar.gz 269763 BLAKE2B b5c70c16a68dc8bae67f273c8ecb423d36fb5379e0dbbc55efffe33ab216162db687fc48004aed84b636ad6b99a79be4cef4838509a18b3a6a81375e1cfd544d SHA512 13b23014939b34096849ecdcd7ffcba0638efa19fbcc3c7348fbcf77a4943236b1009ed1ec07e68acd00b10fdd3d3e809e8a131efe0de17f43bcf794b35755e1
DIST scikit-build-0.16.2.tar.gz 269822 BLAKE2B 4fe7d8f3c3a993f1832d94896068b6bede1eededb4d85e3332137f516819d167102a1eb2fde6dfe4ad187d0483a4e962311a4ca56f3aa5a4eff0c96a187ca052 SHA512 ae8dfd74c638e5cda127b24070c4e491ec51a69b35eae476f5f74a54ba97419d69e984ae7dc132782c77472852358d9d984650db4e6984decad74aadceecfa05

72
dev-python/scikit-build/scikit-build-0.16.2.ebuild Normal file
View File

@@ -0,0 +1,72 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1
DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython extensions"
HOMEPAGE="
https://github.com/scikit-build/scikit-build/
https://pypi.org/project/scikit-build/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/distro[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/cython[${PYTHON_USEDEP}]
dev-python/path[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
dev-python/virtualenv[${PYTHON_USEDEP}]
)
"
distutils_enable_sphinx docs \
dev-python/sphinx_rtd_theme \
dev-python/sphinx-issues
distutils_enable_tests pytest
src_prepare() {
# not packaged
sed -i -e '/cmakedomain/d' docs/conf.py || die
# no pytest-cov
sed -i -e '/addopts =/d' setup.cfg || die
distutils-r1_src_prepare
}
python_test() {
local EPYTEST_DESELECT=(
# sandbox violations
tests/test_hello_cpp.py::test_hello_develop
tests/test_issue274_support_default_package_dir.py
tests/test_issue274_support_one_package_without_package_dir.py
tests/test_issue334_configure_cmakelists_non_cp1252_encoding.py
tests/test_pep518.py
# This fails because of additional item setup.py in sources
tests/test_include_exclude_data.py::test_hello_sdist
tests/test_include_exclude_data.py::test_hello_sdist_with_base
tests/test_issue401_sdist_with_symlinks.py::test_sdist_with_symlinks
tests/test_manifest_in.py::test_manifest_in_sdist
# Wants internet to install things with pip
tests/test_numpy.py::test_pep518_findpython
# TODO
"tests/test_command_line.py::test_hide_listing[True-bdist_wheel]"
)
epytest
}