dev-libs/folks: Version bump

Package-Manager: portage-2.3.1

dev-libs/folks/Manifest

@@ -1 +1,2 @@
 DIST folks-0.11.2.tar.xz 1939808 SHA256 35a80a40e0cf68d5e86eff2ad55320f17427f66377c453ba5a1dbbd71755a1b8 SHA512 cefcbdad7e2924a65c066ecf2cadda61d56e9942b525242b4a2ec410a1ccf25a2db98987f38a5af5fb071e0a881f103462194591165f0699aa01296215926e4d WHIRLPOOL b108b704f3928f4dc4e6a855081c539d8c5262e98d1bab34454cc595b351f074f2691a2a12d4d0734b3d0693de7eac9ec144c45723c82b00dc0a47b1d4428986
+DIST folks-0.11.3.tar.xz 1950448 SHA256 2a2828a7c87fd39e5786f8f2cf0ebe47576a74974f1355c478a6dc747d7bcb64 SHA512 ff7061e07545d3c66045dd6fda1045023778b5cf6a4beb15ebd494076d9133564ec06eda22fe9c61bc91545900a0f0cb0bfa17e29046ef376c12e6b6043faa85 WHIRLPOOL a2f5447cc2aeae37939a5abe0ba4f009ba1155288ef6c8d6ffb47f97f5f2c397ab4887300f8c0e7e1c0f53654a26d79561c55d460184ef8d6adf4f03b7b8a4a4

dev-libs/folks/folks-0.11.3.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Library for aggregating people from multiple sources"
+HOMEPAGE="https://wiki.gnome.org/Projects/Folks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/25" # subslot = libfolks soname version
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+
+# TODO: --enable-profiling
+# Vala isn't really optional, https://bugzilla.gnome.org/show_bug.cgi?id=701099
+IUSE="bluetooth eds +telepathy test tracker utils zeitgeist"
+REQUIRED_USE="bluetooth? ( eds )"
+
+COMMON_DEPEND="
+	$(vala_depend)
+	>=dev-libs/glib-2.40:2
+	dev-libs/dbus-glib
+	>=dev-libs/gobject-introspection-1.30:=
+	>=dev-libs/libgee-0.10:0.8[introspection]
+	dev-libs/libxml2
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+
+	bluetooth? ( >=net-wireless/bluez-5 )
+	eds? ( >=gnome-extra/evolution-data-server-3.13.90:=[vala] )
+	telepathy? ( >=net-libs/telepathy-glib-0.19.9[vala] )
+	tracker? ( >=app-misc/tracker-1:0= )
+	zeitgeist? ( >=gnome-extra/zeitgeist-0.9.14 )
+"
+# telepathy-mission-control needed at runtime; it is used by the telepathy
+# backend via telepathy-glib's AccountManager binding.
+RDEPEND="${COMMON_DEPEND}
+	net-im/telepathy-mission-control
+"
+# folks socialweb backend requires that libsocialweb be built with USE=vala,
+# even when building folks with --disable-vala.
+#
+# FIXME:
+# test? ( bluetooth? ( dbusmock is missing in the tree ) )
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50.0
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	test? (
+		sys-apps/dbus
+		bluetooth? (
+			>=gnome-extra/evolution-data-server-3.9.1
+			>=dev-libs/glib-2.40:2 ) )
+"
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Rebuilding docs needs valadoc, which has no release
+	gnome2_src_configure \
+		$(use_enable bluetooth bluez-backend) \
+		$(use_enable eds eds-backend) \
+		$(use_enable eds ofono-backend) \
+		$(use_enable telepathy telepathy-backend) \
+		$(use_enable tracker tracker-backend) \
+		$(use_enable utils inspect-tool) \
+		$(use_enable test modular-tests) \
+		$(use_enable zeitgeist) \
+		--enable-vala \
+		--enable-import-tool \
+		--disable-docs \
+		--disable-fatal-warnings \
+		--disable-libsocialweb-backend
+}
+
+src_test() {
+	dbus-launch virtx emake check
+}