gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-31 09:08:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 5.38.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2020-10-27 08:01:27 +01:00
parent 3f797d193c
commit 579bb5eeda
2 changed files with 64 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -4,3 +4,4 @@ DIST hypothesis-python-5.36.2.tar.gz 9088227 BLAKE2B 578c28d045f3b3f288d43765d55
DIST hypothesis-python-5.37.4.tar.gz 9092324 BLAKE2B 95ea82c1a64eaa63f0dc662a9c34a51245dc5ebdd95faffe336bce64f02947031e4b8b09eccf45cdb1f5ba851cbc66bcb0baeab74063b9572527c7b3159abd71 SHA512 7eb5299bb9a3206773dda56f560e6ec41f49d052b03782e1c10cd2d5fd62dd8757ccd7ba201612769c8ee5326602af5f1ae1bc0626d88b1f30bae0c610fd42be
DIST hypothesis-python-5.37.5.tar.gz 9092380 BLAKE2B b5bf9f5c5bb1002154ea6041c38b727e926ae65641a05ddd2bfe919fdb7b6457963ddcc5bf1d57a929c57a3912b15a13c52b4568708348f4f308146cf64caa61 SHA512 ddf2db9d8f9318b0b3ae872fdfebbc4ac8376a86816e7c9a0350738a68a4e3adbe41aaf19a8f54471f551542f3252172cc34f5bc140483989ef8c04c5735f044
DIST hypothesis-python-5.38.0.tar.gz 9092764 BLAKE2B ec805c3df17af88e122e9a462c73768b67d420172d72c088add8056b8de64606a8e6c01f82a0ca4fd05520444482e10b488b4ccf2b78b951288c4e1827e1ce12 SHA512 2a4e57ace3c6487598353bd40a9295d8dd05c6b18493d61674bbb403a4bbd863c43af683b59da990cc5add5dedc789462337140c4d2ed7d2c16567fb254261ff
DIST hypothesis-python-5.38.1.tar.gz 9093201 BLAKE2B 093b847524ca1a4a7ec4172585d8cbdc63820165f367a7f5782c0e94ed190f9f271fe0d76f570a5ab95d794951260b93cb4114ac090b56bcdf904e988c00c4c5 SHA512 26db08680464710246bfa3a3dfddbe41e9480e4ce2a50bf75597aa96efe8976d3b7bcf639e2efe9a8bfec64bdfef3fec14093e14cbe8db3f1cf5dafe813a91a0

63
dev-python/hypothesis/hypothesis-5.38.1.ebuild Normal file
View File

@@ -0,0 +1,63 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 eutils multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="cli test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{6..9})
)
"
BDEPEND="
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
>=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
python_prepare() {
if ! use cli || [[ ${EPYTHON} != python* ]]; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
pytest -vv tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
die "Tests fail with ${EPYTHON}"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}