media-libs/libvisual: 0.4.1 + EAPI 8

Closes: https://bugs.gentoo.org/859922
Closes: https://bugs.gentoo.org/871015
Closes: https://bugs.gentoo.org/882811
Signed-off-by: Sebastian Pipping <sping@gentoo.org>

media-libs/libvisual/Manifest

@@ -1 +1,2 @@
 DIST libvisual-0.4.0.tar.bz2 430496 BLAKE2B 068b06ca90dc6b80f5f4bb748962906314341639b26792aa370e834ba1053f3eacdf330c2f59cc6d809b689e50349079b5c6e2331fc1b4594e75decae4b90d3a SHA512 9157f4bcb8b3ba88dea3620ca6dfefdb06322fd46dd16ba893336513e0f27caad22a93639ceb42349faa9b168f0e5f2b202c9b2b5abcfa2f58554a7515941bf4
+DIST libvisual-0.4.1.tar.bz2 560877 BLAKE2B 5429493424cbf7d5d6e17ef6a5219ffb5491a6e0f7ea9d9563021beabfdc22aead0d80924c17904b96cc645ef0dc737fa61680abf152b421ca5f4ac834fc6a19 SHA512 a1417a54d4f0566121db5d08770e7f41559ef7f3704d0da74f1dc316c6b7f16197d843a96382b4122d01251764ccb6ed240fd4e99abc7b0f440c9f43afa9506a

media-libs/libvisual/libvisual-0.4.1.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+DESCRIPTION="Abstraction library between applications and audio visualisation plugins"
+HOMEPAGE="http://libvisual.org/"
+SRC_URI="https://github.com/Libvisual/libvisual/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0.4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="debug nls threads"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.4.0-better-altivec-detection.patch
+)
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/libvisual-0.4/libvisual/lvconfig.h
+)
+
+src_prepare() {
+	default
+
+	# autogenerated, causes problems for out of tree builds
+	rm libvisual/lvconfig.h || die
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--disable-static \
+                --disable-examples \
+		$(use_enable nls) \
+		$(use_enable threads) \
+		$(use_enable debug)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}