dev-python/uvloop: Bump to 0.16.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/uvloop/Manifest

@@ -1,2 +1,3 @@
 DIST uvloop-0.15.2.tar.gz 2092589 BLAKE2B 05c518ba5854fa22fe72a0224856fa0529af0b9432f366b5b1cb0df09a92c787425713fadb85b151363df28800a94ed2a2ad617aaa1c4e854586e49d16f7dd1c SHA512 e398c7ff85da65344a6ab637e9b2f560e9ba61a3be7a3138d546138949359e30bc2e5f8268f1569b73c3881c66d71cf6298038ca1a883be71a33d7ef86d09eed
 DIST uvloop-0.15.3.tar.gz 2094066 BLAKE2B 77ae4634ee31211dba13f41aede4480d70271e042a30a1268e9ad18f5de2b296b84931fb6b2022d2351f33521a84264f74cbc30caa5ff84b0f429bc9f1d426a0 SHA512 5687371a13509bdac0ef7a5ca0f7c78b54d0d9225cbf68cebc6d4fdf3807c2e3346579f5440eb0ff6578088780cc5efb09fba114da0bc0e60ad3f607d9df652f
+DIST uvloop-0.16.0.tar.gz 2129067 BLAKE2B 8a5a5c760b1036428483d2cf1f509784aa61cb69388720775c9555bdb0ce19341cb58fc051ab6f92066a3478acf729513dafafd79f31115b064bf1d3660479de SHA512 dd6dcec38f7f94dc0cf0123302fd6fe404428196b452a80a8258a207654e3f67e210233be3d649668c22b48390232d0347706b1d87fb50016287142c742b806d

dev-python/uvloop/uvloop-0.16.0.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Ultra-fast implementation of asyncio event loop on top of libuv"
+HOMEPAGE="https://github.com/magicstack/uvloop"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 -riscv ~sparc"
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc examples"
+
+RDEPEND=">=dev-libs/libuv-1.11.0:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests setup.py
+
+PATCHES=(
+	"${FILESDIR}"/uvloop-0.15.3-uint64-thread-id.patch
+)
+
+python_prepare_all() {
+	cat <<-EOF >> setup.cfg || die
+		[build_ext]
+		use_system_libuv=1
+	EOF
+
+	# flake8 only
+	rm tests/test_sourcecode.py || die
+	# TODO: broken by cythonize
+	rm tests/test_cython.py || die
+	# force cythonization
+	rm uvloop/loop.c || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_ext --inplace build_sphinx
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && local HTML_DOCS=( "${BUILD_DIR}/sphinx/html/." )
+	distutils-r1_python_install_all
+}