mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-08 06:17:07 -08:00
net-im/mattermost-desktop-bin: add 6.3.0_rc3
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Viorel Munteanu
@@ -4,3 +4,5 @@ DIST mattermost-desktop-6.2.2-linux-arm64.tar.gz 117886439 BLAKE2B f4b4eee6e20ce
|
||||
DIST mattermost-desktop-6.2.2-linux-x64.tar.gz 117833492 BLAKE2B 57ab6eff042c7f2d1c898d6c14296068d86c3fd1caf9d8d40be1f448f8b86885de6b55c6be4851225d8f3aa2152b67ca2beab802eb2ee5320b009bf9fa24cd91 SHA512 226d6fa2e1ffb75a4938a0b9cfb5f610b43e30a423ebbe6642a8df54de3ae7ca5de7b20de3b0309b4460cd29e49a91e9cf41050c88c92835245b191f84cf8d95
|
||||
DIST mattermost-desktop-6.3.0-rc.2-linux-arm64.tar.gz 126597234 BLAKE2B c3dbeb5ef1080bb2b72e861636d1ad52ef6c8a2b924fc82ef72155b50527ad9ae9e97a3618f53a0ba8678f78c64a356f07665b4039546a670df01a4376ed32b9 SHA512 414a9691aee870ba6258e4089a351e2abbd7dc1de4ef522a0372e14a1684c3ebdeb503c973802a77d29f8b51e654637b061161577725247587f917c0ceeb5193
|
||||
DIST mattermost-desktop-6.3.0-rc.2-linux-x64.tar.gz 127748526 BLAKE2B 4a87110a658c77550ded353b3acf3b5e900e0475819a4e56f7d09a12624b2b782b24f888fb8df9bbf213f71ee9f61d83982a679686aa75be8e180aec14176b58 SHA512 e4bb9401363789586b218a12212dd7828c225f8b9ecad805da523373eae6faa6f7d28465b0147621c9cfd04b505cb775745bbc9ff0dcdc377fa9e6dcc61711fc
|
||||
DIST mattermost-desktop-6.3.0-rc.3-linux-arm64.tar.gz 126598087 BLAKE2B 7d4030dc5656210065b589b26c79e907817713083115842ca06a3994baa0161c9d38d20fbe75ec8fd57bdd77249d2a830d07cedb0afea9ee609fa3459edbb361 SHA512 278771b8db92d7ed155d021614b4fec562fc6049222c81ee634080f13b851ce411bc653dd742a307d12b3bd8b430e970cd1541f50ce5d0f4a043cd3a1fc20421
|
||||
DIST mattermost-desktop-6.3.0-rc.3-linux-x64.tar.gz 127749350 BLAKE2B ca2f5603f5062aa720ce6ef8a062e1b19a636a16d3d0e9ad816ec6997ae6542f622ff3f871b6d9f9119787e5f1e509ff557a0b9027232f63bf7fbf2c0954c82e SHA512 64a57571fa98bf6c987001b94145b83dd6928fa8b158f57489bb23d7ced6104b909c979038e8ebaa89376ad743d844f4fabd700ed4367d8f83a9d570a4ff4d36
|
||||
|
||||
@@ -0,0 +1,123 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
MY_PN="${PN%-*}"
|
||||
MY_PV="${PV/_rc/-rc.}"
|
||||
|
||||
inherit desktop toolchain-funcs xdg
|
||||
|
||||
DESCRIPTION="Mattermost Desktop application"
|
||||
HOMEPAGE="https://mattermost.com/"
|
||||
|
||||
SRC_URI="
|
||||
amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
|
||||
arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
|
||||
"
|
||||
S="${WORKDIR}"
|
||||
|
||||
LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
|
||||
SLOT="0"
|
||||
if [[ ${PV} != *rc* ]]; then
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
fi
|
||||
|
||||
RDEPEND="
|
||||
>=app-accessibility/at-spi2-core-2.46.0:2[X]
|
||||
dev-libs/expat
|
||||
dev-libs/glib:2
|
||||
dev-libs/nspr
|
||||
dev-libs/nss
|
||||
dev-libs/wayland
|
||||
media-libs/alsa-lib
|
||||
media-libs/mesa
|
||||
net-print/cups
|
||||
sys-apps/dbus
|
||||
sys-libs/glibc
|
||||
virtual/libudev
|
||||
x11-libs/cairo
|
||||
x11-libs/gdk-pixbuf:2
|
||||
x11-libs/gtk+:3[X]
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrandr
|
||||
x11-libs/libdrm
|
||||
x11-libs/libxcb
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/pango
|
||||
"
|
||||
|
||||
BDEPEND="
|
||||
dev-util/debugedit
|
||||
"
|
||||
|
||||
QA_PREBUILT="
|
||||
opt/mattermost-desktop/mattermost-desktop
|
||||
opt/mattermost-desktop/chrome_crashpad_handler
|
||||
opt/mattermost-desktop/libnode.so
|
||||
opt/mattermost-desktop/libffmpeg.so
|
||||
opt/mattermost-desktop/libGLESv2.so
|
||||
opt/mattermost-desktop/libEGL.so
|
||||
opt/mattermost-desktop/libvk_swiftshader.so
|
||||
opt/mattermost-desktop/libvulkan.so.1
|
||||
opt/mattermost-desktop/resources/*
|
||||
"
|
||||
|
||||
DOCS=(
|
||||
NOTICE.txt
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
if use amd64; then
|
||||
find . '(' -name koffi-linux-arm64 -o -name musl_x64 ')' -exec rm -r {} + || die
|
||||
elif use arm64; then
|
||||
find . '(' -name koffi-linux-x64 -o name musl_arm64 ')' -exec rm -r {} + || die
|
||||
fi
|
||||
|
||||
# file collision with FEATURES=splitdebug, see bug #961437
|
||||
tc-export OBJCOPY
|
||||
find . -type f ! -name '*$(*)*' -print0 | while IFS= read -r -d '' file; do
|
||||
if file "${file}" | grep -qE "ELF (32|64)-bit"; then
|
||||
${OBJCOPY} --remove-section .note.gnu.build-id "${file}" || die
|
||||
debugedit -b "${EPREFIX}/opt/${MY_PN}" -d "/usr/lib/debug" -i "${file}" || die
|
||||
fi
|
||||
done
|
||||
}
|
||||
|
||||
src_install() {
|
||||
if use amd64; then
|
||||
cd mattermost-desktop-${MY_PV}-linux-x64 || die
|
||||
elif use arm64; then
|
||||
cd mattermost-desktop-${MY_PV}-linux-arm64 || die
|
||||
fi
|
||||
newicon app_icon.png ${MY_PN}.png
|
||||
|
||||
insinto "/opt/${MY_PN}/locales"
|
||||
doins locales/*.pak
|
||||
|
||||
insinto "/opt/${MY_PN}/resources"
|
||||
doins -r resources/*.asar*
|
||||
|
||||
insinto "/opt/${MY_PN}"
|
||||
doins *.pak *.bin *.dat
|
||||
exeinto "/opt/${MY_PN}"
|
||||
doexe *.so *.so.* "${MY_PN}" chrome_crashpad_handler
|
||||
|
||||
dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
|
||||
|
||||
make_desktop_entry --eapi9 mattermost-desktop \
|
||||
-a "--enable-features=WaylandWindowDecorations --ozone-platform-hint=auto %U" \
|
||||
-d Mattermost.Desktop \
|
||||
-n Mattermost \
|
||||
-i mattermost-desktop \
|
||||
-c "Network;InstantMessaging;" \
|
||||
-e "MimeType=x-scheme-handler/mattermost;" -e "StartupWMClass=Mattermost.Desktop"
|
||||
|
||||
einstalldocs
|
||||
}
|
||||
Reference in New Issue
Block a user