app-containers/cri-o: add 1.36.5

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

app-containers/cri-o/Manifest

@@ -1 +1,2 @@
 DIST cri-o-1.36.1.tar.gz 21684722 BLAKE2B 5b60a98889f502068db449381fdce4d28cb7ce513fa95058fcf704709f3aac46dd07f74e252053208a82d40f577fb6c05b0e1ef296a237ea285121abb6044f72 SHA512 3ab9dd8c202a9d3048e6c6262b5390d10b3d04d0bc6c52e874b5742435c3ecdac45559f47747918d907c469cc81f0fd7ae2146128e5d0af15db0212395da431f
+DIST cri-o-1.36.5.tar.gz 21578714 BLAKE2B bf3e95c76869e029a7c14d0f44df54b7dba7ad3204d30becde7a8b591870c40a2c1715b5f65aa868dbab3c89b6612d267ab214b97719e74d58c5cc6b45106ede SHA512 846993f86eb08b14b8ff9b4194d0b56f579cf31d80c610c291e6eb9e083eac37ff13d1bf8f684c0ba18ba9a72261f2e714c2f08a47d07fa6039baae7fb80e801

app-containers/cri-o/cri-o-1.36.5.ebuild

@@ -0,0 +1,100 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+EGIT_COMMIT=dcd680fd83e792a9b625d38cc03c609722bd0baf
+
+inherit go-module
+
+DESCRIPTION="OCI-based implementation of Kubernetes Container Runtime Interface"
+HOMEPAGE="https://cri-o.io/"
+SRC_URI="https://github.com/cri-o/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="btrfs +device-mapper selinux systemd"
+
+DEPEND="
+	app-crypt/gpgme:=
+	app-containers/conmon
+	>=app-containers/container-libs-0.68.0
+	app-containers/runc
+	dev-libs/glib:=
+	dev-libs/libassuan:=
+	dev-libs/libgpg-error:=
+	net-firewall/conntrack-tools
+	net-firewall/iptables
+	app-containers/cni-plugins
+	net-misc/socat
+	sys-apps/iproute2
+	sys-libs/libseccomp:=
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )
+	selinux? ( sys-libs/libselinux:= )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="${DEPEND}
+	!<app-containers/podman-1.3.2-r1
+	selinux? ( sec-policy/selinux-crio )
+"
+BDEPEND="
+	dev-go/go-md2man
+	>=dev-lang/go-1.26.4
+	sys-apps/which
+"
+
+src_prepare() {
+	default
+
+	echo ".NOTPARALLEL: binaries docs" >> Makefile || die
+
+	sed -e '/STRIP/d' -e 's/ -Werror / /' -i pinns/Makefile || die
+
+	sed -e 's:/usr/local/bin:/usr/bin:' \
+		-i contrib/systemd/* || die
+}
+
+src_compile() {
+	[[ -f hack/btrfs_installed_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+		hack/btrfs_installed_tag.sh || die; }
+
+	[[ -f hack/selinux_tag.sh ]] || die
+	use selinux || { echo -e "#!/bin/sh\ntrue" > \
+		hack/selinux_tag.sh || die; }
+
+	mkdir -p bin || die
+	emake all \
+		GOBIN="${S}/bin" \
+		GO_BUILD="go build ${GOFLAGS}" \
+		BUILD_COMMIT="${EGIT_COMMIT}" \
+		SHRINKFLAGS="-w" \
+		GO_MD2MAN="$(which go-md2man)"
+}
+
+src_install() {
+	emake install install.config install.systemd \
+		DESTDIR="${D}" \
+		BUILD_COMMIT="${EGIT_COMMIT}" \
+		GO_MD2MAN="$(which go-md2man)" \
+		PREFIX="${D}${EPREFIX}/usr"
+	keepdir /etc/crio
+	mv "${ED}/etc/crio/crio.conf"{,.example} || die
+
+	newinitd "${FILESDIR}/crio.initd" crio
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+
+	# Suppress crio log error messages triggered if these don't exist.
+	keepdir /etc/containers/oci/hooks.d
+	keepdir /usr/share/containers/oci/hooks.d
+
+	# Suppress crio "Missing CNI default network" log message.
+	keepdir /etc/cni/net.d
+	insinto /etc/cni/net.d
+	doins contrib/cni/99-loopback.conflist
+	dosym -r /usr/share/containers/policy.json /etc/containers/policy.json #979676
+}