mail-filter/postforward: EAPI=8, use go-module.eclass

Closes: https://bugs.gentoo.org/844709
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

mail-filter/postforward/postforward-1.1.1-r1.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module
+
+DESCRIPTION="Postfix Sender Rewriting Scheme forwarding agent"
+HOMEPAGE="https://github.com/zoni/postforward"
+SRC_URI="https://github.com/zoni/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+
+RDEPEND="mail-filter/postsrsd"
+
+PATCHES=(
+	"${FILESDIR}/${P}-apply-sendmail-path.patch"
+)
+
+src_unpack() {
+	# This package has no dependencies, but go-module_src_unpack requires this directory
+	mkdir -p "${S}/vendor" || die
+
+	go-module_src_unpack
+}
+
+src_prepare() {
+	default
+
+	# Dynamically fix EPREFIX lines made by ${PN}_apply-sendmail-path.patch
+	sed -e "s/@GENTOO_PORTAGE_EPREFIX@/${EPREFIX}/" -i ${PN}.go || die
+}
+
+src_compile() {
+	ego build -o ${PN} ${PN}.go
+}
+
+src_install() {
+	einstalldocs
+	dosbin "${PN}"
+}

mail-filter/postforward/postforward-1.1.1.ebuild

@@ -1,47 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit golang-build
-
-DESCRIPTION="Postfix Sender Rewriting Scheme forwarding agent"
-EGO_PN="${PN}"
-SRC_URI="https://github.com/zoni/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-HOMEPAGE="https://github.com/zoni/postforward"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="amd64 x86"
-
-DEPEND="
-	dev-lang/go:0"
-RDEPEND="
-	mail-filter/postsrsd"
-
-PATCHES=( "${FILESDIR}/${PN}_apply-sendmail-path.patch" )
-
-src_prepare() {
-	default
-
-	# Dynamically fix EPREFIX lines made by ${PN}_apply-sendmail-path.patch
-	sed -i -e "s/@GENTOO_PORTAGE_EPREFIX@/${EPREFIX}/" *.go || die
-
-	# go build assumes files will be in src dir, but
-	# source files are in root in this package, so move
-	# them.
-	local new_src_dir="${S}/src/${EGO_PN}"
-	# Freak out if there's already something there because
-	# it means the package has changed and we'll need to
-	# adjust to it.
-	[[ -e "${new_src_dir}" ]] && die "${new_src_dir} already exists"
-	mkdir -p "${new_src_dir}" || die
-	mv *.go "${new_src_dir}" || die
-}
-
-# Standard golang-build src_install complains about pkg not
-# existing, so we go custom.
-src_install() {
-	einstalldocs
-	dosbin "${PN}"
-}